可视化材料的阻止本领: Wolfram语言 11 的新功能

可视化材料的阻止本领

放射性粒子在穿越物质时会失去动能，最终静止或被吸收. 本示例探索物质被 α 粒子辐照时的阻止本领。

绘制生物组织被 α 粒子以不同冲击能辐照时的线性阻止本领. 纵轴表示粒子穿越每厘米时所失去的平均能量.

In[1]:=

ListLogLinearPlot[
 Table[{Quantity[10^x, "Electronvolts"], 
   StoppingPowerData[
    "A150TissueEquivalentPlastic", {"Particle" -> 
      Entity["Particle", "AlphaParticle"], 
     "Energy" -> Quantity[10^x, "Electronvolts"]}, 
    "LinearStoppingPower"]}, {x, 3, 8, 0.1}], AxesLabel -> Automatic]

Out[1]=

现在探讨由铀原子放射的阿尔法粒子在穿过生物组织时线性阻止本领的变化. 这是粒子的初始动能.

In[2]:=

initialKE = 
 IsotopeData[Entity["Isotope", "Uranium235"], "BindingEnergy"]

Out[2]=

显示完整的 Wolfram 语言输入

In[3]:=

dEByDxVal[k_Real?Positive] := 
  QuantityMagnitude[
    StoppingPowerData[
     "A150TissueEquivalentPlastic", {"Particle" -> 
       Entity["Particle", "AlphaParticle"], 
      "Energy" -> Quantity[k, "Megaelectronvolts"]}, 
     "LinearStoppingPower"]]/10000;
dEByDxVal[k_Real] := 0

In[4]:=

sol = NDSolveValue[{KiM'[x] == -dEByDxVal[KiM[x]], 
    KiM[0] == QuantityMagnitude[initialKE],
      WhenEvent[KiM[x] <= 0, "StopIntegration"]}, KiM, {x, 0, 60},
    PrecisionGoal -> 3];

表示粒子在材料中通过时其动能的衰减，直到它在约处停止.

显示完整的 Wolfram 语言输入

In[5]:=

Plot[sol[x], {x, 0, 60}, Frame -> True, GridLines -> Automatic, 
 FrameLabel -> {"distance traveled (\[Micro]m)", 
   Row[{"KE", " (", Quantity[None, "Megaelectronvolts"], ")"}]}]

Out[5]=

这表示每单位长度上能量损失的速率.

显示完整的 Wolfram 语言输入

In[6]:=

Plot[dEByDxVal[sol[x]], {x, 0, 60}, Frame -> True, 
 GridLines -> Automatic, 
 FrameLabel -> {"distance traveled (\[Micro]m)", 
   Row[{"\[DifferentialD]", Style["E", Italic], "/", 
     "\[DifferentialD]", Style["x", Italic], " (", 
     Quantity[None, "Megaelectronvolts"/"Micrometers"], ")"}]}]

Out[6]=

Wolfram 语言™

可视化材料的阻止本领

相关范例