Wolfram 언어

Knowledgebase의 확장

물질의 저지 능력 시각화

방사선 입자는 물질내를 이동할 때 운동에 의한 에너지를 잃고 결국 중지하거나 흡수되거나합니다. 이 예제에서는 알파 입자에 방사선을 비출 때 물질의 저지 능력에 대해 조사해 봅니다.

다양한 충격 에너지를 가진 알파 입자에 방사선을 비출 때 생물 조직의 선형 저지 능력을 플롯합니다. 세로축은 입자가 1센티미터 이동할 때마다의 평균 손실 에너지량을 나타냅니다.

In[1]:=
Click for copyable input
ListLogLinearPlot[ Table[{Quantity[10^x, "Electronvolts"], StoppingPowerData[ "A150TissueEquivalentPlastic", {"Particle" -> Entity["Particle", "AlphaParticle"], "Energy" -> Quantity[10^x, "Electronvolts"]}, "LinearStoppingPower"]}, {x, 3, 8, 0.1}], AxesLabel -> Automatic]
Out[1]=

우라늄 원자에서 방출되는 알파 입자에 대해 입자가 생물 구조를 통과함에 따라 그 선형 저지 능력이 어떻게 변화 하는지를 조사합니다. 이것은 입자의 초기 운동 에너지를 나타냅니다.

In[2]:=
Click for copyable input
initialKE = IsotopeData[Entity["Isotope", "Uranium235"], "BindingEnergy"]
Out[2]=
전체 Wolfram 언어 입력 표시하기
In[3]:=
Click for copyable input
dEByDxVal[k_Real?Positive] := QuantityMagnitude[ StoppingPowerData[ "A150TissueEquivalentPlastic", {"Particle" -> Entity["Particle", "AlphaParticle"], "Energy" -> Quantity[k, "Megaelectronvolts"]}, "LinearStoppingPower"]]/10000; dEByDxVal[k_Real] := 0
In[4]:=
Click for copyable input
sol = NDSolveValue[{KiM'[x] == -dEByDxVal[KiM[x]], KiM[0] == QuantityMagnitude[initialKE], WhenEvent[KiM[x] <= 0, "StopIntegration"]}, KiM, {x, 0, 60}, PrecisionGoal -> 3];

입자가 약 로 정지 할 때까지 이동시 운동 에너지의 감소를 나타냅니다.

전체 Wolfram 언어 입력 표시하기
In[5]:=
Click for copyable input
Plot[sol[x], {x, 0, 60}, Frame -> True, GridLines -> Automatic, FrameLabel -> {"distance traveled (\[Micro]m)", Row[{"KE", " (", Quantity[None, "Megaelectronvolts"], ")"}]}]
Out[5]=

다음은 길이 단위당 에너지의 손실 비율을 나타냅니다.

전체 Wolfram 언어 입력 표시하기
In[6]:=
Click for copyable input
Plot[dEByDxVal[sol[x]], {x, 0, 60}, Frame -> True, GridLines -> Automatic, FrameLabel -> {"distance traveled (\[Micro]m)", Row[{"\[DifferentialD]", Style["E", Italic], "/", "\[DifferentialD]", Style["x", Italic], " (", Quantity[None, "Megaelectronvolts"/"Micrometers"], ")"}]}]
Out[6]=

관련 예제

de en es fr ja pt-br ru zh