Wolfram Language

Expansão da base de conhecimento

Visualize o poder de parada de materiais

Partículas de radiação perdem energia cinética quando viajam através da matéria e, eventualmente, param ou são absorvidas. Este exemplo explora o poder de parada das substâncias quando se irradiam com partículas alfa.

Faça um gráfico do poder de parada linear de tecido biológico quando irradiado com partículas alfa de diferentes energias de impacto. O eixo vertical representa a quantidade de energia que as partículas perdem em média por centímetro percorrido.

In[1]:=
Click for copyable input
ListLogLinearPlot[ Table[{Quantity[10^x, "Electronvolts"], StoppingPowerData[ "A150TissueEquivalentPlastic", {"Particle" -> Entity["Particle", "AlphaParticle"], "Energy" -> Quantity[10^x, "Electronvolts"]}, "LinearStoppingPower"]}, {x, 3, 8, 0.1}], AxesLabel -> Automatic]
Out[1]=

Agora explore como o poder de parada linear muda para uma partícula alfa emitida de um átomo de urânio quando a partícula viaja através dos tecidos biológicos. Esta é a energia cinética inicial da partícula.

In[2]:=
Click for copyable input
initialKE = IsotopeData[Entity["Isotope", "Uranium235"], "BindingEnergy"]
Out[2]=
mostre o input completo da Wolfram Language
In[3]:=
Click for copyable input
dEByDxVal[k_Real?Positive] := QuantityMagnitude[ StoppingPowerData[ "A150TissueEquivalentPlastic", {"Particle" -> Entity["Particle", "AlphaParticle"], "Energy" -> Quantity[k, "Megaelectronvolts"]}, "LinearStoppingPower"]]/10000; dEByDxVal[k_Real] := 0
In[4]:=
Click for copyable input
sol = NDSolveValue[{KiM'[x] == -dEByDxVal[KiM[x]], KiM[0] == QuantityMagnitude[initialKE], WhenEvent[KiM[x] <= 0, "StopIntegration"]}, KiM, {x, 0, 60}, PrecisionGoal -> 3];

Represente a diminuição da energia cinética enquanto a partícula avança através do material até que pare aproximadamente a .

mostre o input completo da Wolfram Language
In[5]:=
Click for copyable input
Plot[sol[x], {x, 0, 60}, Frame -> True, GridLines -> Automatic, FrameLabel -> {"distance traveled (\[Micro]m)", Row[{"KE", " (", Quantity[None, "Megaelectronvolts"], ")"}]}]
Out[5]=

Isto representa a taxa de perda de energia por unidade de comprimento.

mostre o input completo da Wolfram Language
In[6]:=
Click for copyable input
Plot[dEByDxVal[sol[x]], {x, 0, 60}, Frame -> True, GridLines -> Automatic, FrameLabel -> {"distance traveled (\[Micro]m)", Row[{"\[DifferentialD]", Style["E", Italic], "/", "\[DifferentialD]", Style["x", Italic], " (", Quantity[None, "Megaelectronvolts"/"Micrometers"], ")"}]}]
Out[6]=

Exemplos Relacionados

de en es fr ja ko ru zh