Язык Wolfram Language

Новые визуализации предметных областей

Макет хронологии и положения меток

Создайте хронологию известных людей из эпохи романтизма.

In[1]:=
Click for copyable input
romanticerapeople = DeleteCases[ EntityValue[ Entity["HistoricalPeriod", "RomanticEra"][ "PeopleInvolved"], {"BirthDate", "DeathDate", "Name", "Image", "Occupation"}], {__, _Missing}];
In[2]:=
Click for copyable input
lifespan = GroupBy[romanticerapeople, Last -> (Tooltip[ Labeled[Interval@#[[1 ;; 2]], #[[3]], "StartBubble"], Labeled[#[[4]], DateDifference[#[[1]], #[[2]], "Year"]]] &)];

Отобразите каждого композитора в его собственном ряду.

In[3]:=
Click for copyable input
TimelinePlot[lifespan[{"composer"}], PlotLayout -> "Stacked", LabelStyle -> 12, ImageSize -> 550, PlotLabel -> "Romantic Era Composers", PlotTheme -> "Grid"]
Out[3]=

Используйте минимальное количество рядов.

In[4]:=
Click for copyable input
TimelinePlot[lifespan[{"composer"}], PlotLayout -> "Grouped", LabelStyle -> 12, ImageSize -> 550, PlotLabel -> "Romantic Era Composers", PlotTheme -> "Grid"]
Out[4]=

Разместите метку в конце временного отрезка.

In[5]:=
Click for copyable input
lifespan = GroupBy[romanticerapeople, Last -> (Tooltip[ Labeled[Interval@#[[1 ;; 2]], #[[3]], "EndBubble"], Labeled[#[[4]], DateDifference[#[[1]], #[[2]], "Year"]]] &)];
In[6]:=
Click for copyable input
TimelinePlot[lifespan[{"composer"}], LabelStyle -> 12, ImageSize -> 550, PlotLabel -> "Romantic Era Composers", PlotTheme -> "Grid"]
Out[6]=

При многочисленных записях данных и ограниченном пространстве, расположите метки после временных отрезков.

In[7]:=
Click for copyable input
lifespan = GroupBy[romanticerapeople, Last -> (Tooltip[Labeled[Interval@#[[1 ;; 2]], #[[3]], After], Labeled[#[[4]], DateDifference[#[[1]], #[[2]], "Year"]]] &)];
In[8]:=
Click for copyable input
TimelinePlot[Values@lifespan, PlotLayout -> "Grouped", LabelStyle -> 14, AspectRatio -> 1/1.2, ImageSize -> 450, PlotLegends -> LineLegend[Flatten@Keys[lifespan], LegendLayout -> "ReversedColumn"], PlotTheme -> "Web"]
Out[8]=

Используйте компактную укладку для наборов данных.

In[9]:=
Click for copyable input
TimelinePlot[Values@lifespan, PlotLayout -> "Packed", LabelStyle -> 14, AspectRatio -> 1/1.2, ImageSize -> 450, PlotLegends -> LineLegend[Flatten@Keys[lifespan], LegendLayout -> "ReversedColumn"], PlotTheme -> "Web"]
Out[9]=

Родственные примеры

de en es fr ja ko pt-br zh