Wolfram Language

Fonctionnalités au niveau des systèmes

Chiffrez et stockez une carte au trésor dans le cloud

Toute expression de Wolfram Language peut être chiffrée.

Générez une clé symétrique forte dérivée d'un mot de passe secret en utilisant la méthode de Blowfish.

In[1]:=
Click for copyable input
skeletonKey = GenerateSymmetricKey["Avast ye!", Method -> "Blowfish"]
Out[1]=

Chiffrez le lieu du message, stockez-le dans un GeoMarker et visualisez-le en utilisant GeoGraphics avec la clé générée.

Afficher l'entrée complète de Wolfram Language
In[2]:=
Click for copyable input
treasureMap = GeoGraphics[{GeoMarker[GeoPosition[{15.9429, -86.5031}], Text[Style["x", FontFamily -> "Bradley Hand", FontSize -> 24]]]}, FrameLabel -> "Where the Gold is Buried", Frame -> True, ImageSize -> 300, GeoBackground -> "StreetMapNoLabels"]
Out[2]=
In[3]:=
Click for copyable input
hiddenTreasure = Encrypt[skeletonKey, treasureMap]
Out[3]=

Maintenant que les données sont chiffrées en toute sécurité en utilisant une clé locale, téléchargez la carte dans Wolfram Cloud.

In[4]:=
Click for copyable input
stowed = CloudPut[hiddenTreasure]
Out[4]=

Pour brouiller les pistes, supprimez la carte et la clé d'origine en utilisant Clear.

In[5]:=
Click for copyable input
Clear[hiddenTreasure]
In[6]:=
Click for copyable input
Clear[skeletonKey]

Étant donné que la clé a été calculée à l'aide d'un mot de passe, vous pouvez créer une nouvelle clé en utilisant l'entrée d'origine.

In[7]:=
Click for copyable input
newKey = GenerateSymmetricKey["Avast ye!", Method -> "Blowfish"]
Out[7]=

La nouvelle clé peut maintenant être utilisée pour faire référence à la carte dans le cloud.

In[8]:=
Click for copyable input
reclaimedMap = Decrypt[newKey, CloudGet[stowed]]
Out[8]=

Extrayez l'emplacement du trésor.

In[9]:=
Click for copyable input
treasureLocation = reclaimedMap[[3, 2]]
Out[9]=

Demandez la direction.

In[10]:=
Click for copyable input
TravelDirections[{$GeoLocation, treasureLocation}]
Out[10]=

Comme il n'y a pas d'accès en voiture pour aller au trésor, calculer la distance en utilisant GeoDistance.

In[11]:=
Click for copyable input
GeoDistance[$GeoLocation, treasureLocation]
Out[11]=

Compte tenu de la distance, localisez l'aéroport le plus proche du trésor.

In[12]:=
Click for copyable input
airport = First[GeoNearest["Airport", treasureLocation]]
Out[12]=

La distance entre l'aéroport et le trésor.

In[13]:=
Click for copyable input
GeoDistance[airport, treasureLocation]
Out[13]=

Exemples connexes

de en es ja ko pt-br ru zh