Wolfram 언어™

클라우드에서 보물 찾기 지도의 암호화 및 보관

모든 Wolfram 언어식은 암호화가 가능합니다.

Blowfish 방법을 사용한 비밀 암호에서 파생되어진 강력한 대칭 키를 생성합니다.

In[1]:=

skeletonKey = GenerateSymmetricKey["Avast ye!", Method -> "Blowfish"]

Out[1]=

생성 된 키를 사용하여 보물의 소재를 암호화한 후, GeoMarker에 보관하고 GeoGraphics를 사용하여 시각화합니다.

In[2]:=

treasureMap = GeoGraphics[{GeoMarker[GeoPosition[{15.9429, -86.5031}], Text[Style["x", FontFamily -> "Bradley Hand", FontSize -> 24]]]}, FrameLabel -> "Where the Gold is Buried", Frame -> True, ImageSize -> 300, GeoBackground -> "StreetMapNoLabels"]

Out[2]=

In[3]:=

hiddenTreasure = Encrypt[skeletonKey, treasureMap]

Out[3]=

이제 로컬 키를 사용하여 데이터는 안전하게 암호화 되었습니다. 지도를 Wolfram Cloud에 업로드합니다.

In[4]:=

stowed = CloudPut[hiddenTreasure]

Out[4]=

추적되지 않도록 오리지널 지도와 키를 Clear를 사용하여 제거합니다.

In[5]:=

Clear[hiddenTreasure]

In[6]:=

Clear[skeletonKey]

이 키는 암호를 사용하여 만들어진 것이므로, 오리지널 입력을 사용한 새로운 키 생성이 가능합니다.

In[7]:=

newKey = GenerateSymmetricKey["Avast ye!", Method -> "Blowfish"]

Out[7]=

이 새로운 키를 사용하여 클라우드에 배치 된 지도를 참조 할 수있습니다.

In[8]:=

reclaimedMap = Decrypt[newKey, CloudGet[stowed]]

Out[8]=

보물의 소재를 추출합니다.

In[9]:=

treasureLocation = reclaimedMap[[3, 2]]

Out[9]=

운전 경로를 묻습니다.

In[10]:=

TravelDirections[{$GeoLocation, treasureLocation}]

Out[10]=

GeoDistance를 사용하여 거리를 조사합니다.

In[11]:=

GeoDistance[$GeoLocation, treasureLocation]

Out[11]=

이 거리를 바탕으로 보물에 가장 가까운 공항을 찾습니다.

In[12]:=

airport = First[GeoNearest["Airport", treasureLocation]]

Out[12]=

그 공항에서 보물까지의 거리를 계산합니다.

In[13]:=

GeoDistance[airport, treasureLocation]

Out[13]=