日付のある時系列にフィルタを適用する
WeatherDataを使って,指定された日付の気温を得る.欠損データを補間するためにMissingDataMethodを指定して新しい時系列を生成する.
In[1]:=
![Click for copyable input](assets.ja/filter-time-series-with-dates/In_93.png)
data = TimeSeries[
WeatherData["Chicago",
"Temperature", {{2015, 1, 1}, {2015, 12, 31}}],
MissingDataMethod -> "Interpolation"]
Out[1]=
![](assets.ja/filter-time-series-with-dates/O_49.png)
In[2]:=
![Click for copyable input](assets.ja/filter-time-series-with-dates/In_94.png)
DateListPlot[data, FrameLabel -> Automatic]
Out[2]=
![](assets.ja/filter-time-series-with-dates/O_50.png)
1ヶ月の範囲でMinFilterを使い,その年の初氷と終氷がいつであったかを分析する.
In[3]:=
![Click for copyable input](assets.ja/filter-time-series-with-dates/In_95.png)
minF = MinFilter[data, Quantity[1, "Month"]];
完全なWolfram言語入力を表示する
Out[5]=
![](assets.ja/filter-time-series-with-dates/O_51.png)
春の終氷の次の日.
In[6]:=
![Click for copyable input](assets.ja/filter-time-series-with-dates/In_98.png)
spring = TimeSeriesWindow[minF, {"15 April 2015", "15 May 2015"}];
In[7]:=
![Click for copyable input](assets.ja/filter-time-series-with-dates/In_99.png)
DateObject[
First@FirstCase[
spring["Path"], _?(#[[2]] > Quantity[0, "DegreesCelsius"] &)]]
Out[7]=
![](assets.ja/filter-time-series-with-dates/O_52.png)
秋の初氷.
In[8]:=
![Click for copyable input](assets.ja/filter-time-series-with-dates/In_100.png)
fall = TimeSeriesWindow[minF, {"1 Oct 2015", "31 Oct 2015"}];
In[9]:=
![Click for copyable input](assets.ja/filter-time-series-with-dates/In_101.png)
DateObject[
First@FirstCase[
fall["Path"], _?(#[[2]] <= Quantity[0, "DegreesCelsius"] &)]]
Out[9]=
![](assets.ja/filter-time-series-with-dates/O_53.png)