日付のある時系列にフィルタを適用する: Wolfram言語 11の新機能

日付のある時系列にフィルタを適用する

WeatherDataを使って，指定された日付の気温を得る．欠損データを補間するためにMissingDataMethodを指定して新しい時系列を生成する．

In[1]:=

data = TimeSeries[
  WeatherData["Chicago", 
   "Temperature", {{2015, 1, 1}, {2015, 12, 31}}], 
  MissingDataMethod -> "Interpolation"]

Out[1]=

In[2]:=

DateListPlot[data, FrameLabel -> Automatic]

Out[2]=

1ヶ月の範囲でMinFilterを使い，その年の初氷と終氷がいつであったかを分析する．

In[3]:=

minF = MinFilter[data, Quantity[1, "Month"]];

完全なWolfram言語入力を表示する

In[4]:=

freezeline = {{minF["FirstDate"], 0}, {minF["LastDate"], 0}};

In[5]:=

DateListPlot[{data, minF, freezeline}, FrameLabel -> Automatic]

Out[5]=

春の終氷の次の日．

In[6]:=

spring = TimeSeriesWindow[minF, {"15 April 2015", "15 May 2015"}];

In[7]:=

DateObject[
 First@FirstCase[
   spring["Path"], _?(#[[2]] > Quantity[0, "DegreesCelsius"] &)]]

Out[7]=

秋の初氷．

In[8]:=

fall = TimeSeriesWindow[minF, {"1 Oct 2015", "31 Oct 2015"}];

In[9]:=

DateObject[
 First@FirstCase[
   fall["Path"], _?(#[[2]] <= Quantity[0, "DegreesCelsius"] &)]]

Out[9]=