用日期滤波时间序列: Wolfram语言 11 的新功能

用日期滤波时间序列

用 WeatherData 获取给定日期的温度. 然后用特定的 MissingDataMethod 填补遗漏的数据来创建一个新的时间序列.

In[1]:=

data = TimeSeries[
  WeatherData["Chicago", 
   "Temperature", {{2015, 1, 1}, {2015, 12, 31}}], 
  MissingDataMethod -> "Interpolation"]

Out[1]=

In[2]:=

DateListPlot[data, FrameLabel -> Automatic]

Out[2]=

用范围为一个月的 MinFilter 来分析那一年最后一次和第一次冰冻发生在什么时候.

In[3]:=

minF = MinFilter[data, Quantity[1, "Month"]];

显示完整的 Wolfram 语言输入

In[4]:=

freezeline = {{minF["FirstDate"], 0}, {minF["LastDate"], 0}};

In[5]:=

DateListPlot[{data, minF, freezeline}, FrameLabel -> Automatic]

Out[5]=

春天最后一个冰冻日后的第一天.

In[6]:=

spring = TimeSeriesWindow[minF, {"15 April 2015", "15 May 2015"}];

In[7]:=

DateObject[
 First@FirstCase[
   spring["Path"], _?(#[[2]] > Quantity[0, "DegreesCelsius"] &)]]

Out[7]=

秋天第一个冰冻日.

In[8]:=

fall = TimeSeriesWindow[minF, {"1 Oct 2015", "31 Oct 2015"}];

In[9]:=

DateObject[
 First@FirstCase[
   fall["Path"], _?(#[[2]] <= Quantity[0, "DegreesCelsius"] &)]]

Out[9]=