Arranjos de quantidades

QuantityArray permite o armazenamento eficiente e a manipulação de arranjos de objetos de Quantity, e portanto é ideal para análise de dados com unidades físicas. Continuando com a integração das quantidades em todo o sistema, várias funções agora compreendem ou retornam objetos de QuantityArray.

Faça uma amostra de objetos de QuantityDistribution.

In[1]:=

RandomVariate[ParetoDistribution[Quantity[500., "USDollars"], 4], 300]

Out[1]=

Um objeto de QuantityArray equivalente a um arranjo normal de elementos Quantity.

In[2]:=

RandomVariate[ParetoDistribution[Quantity[500., "USDollars"], 4], 300]; Normal[Take[%, 10]]

Out[2]=

Cálcule ou faça download de arranjos de dados geográficos, como elevação ou dados de campo magnético.

In[3]:=

GeoElevationData[Entity["Country", "UnitedStates"]]

Out[3]=

In[4]:=

GeomagneticModelData[ Entity["GeographicRegion", "Antarctica"], "Magnitude"]

Out[4]=

Manipule arranjos de ângulos de latitude e longitude.

In[5]:=

GeoElevationData[ Entity["Country", "UnitedStates"], "Undulation", GeoPosition]

Out[5]=

In[6]:=

GeoElevationData[ Entity["Country", "UnitedStates"], "Undulation", GeoPosition]; LatitudeLongitude[%]

Out[6]=

Obtenha um arranjo de dados para o componente vertical do campo gravitacional sobre a China.

In[7]:=

data = GeogravityModelData[Entity["Country", "China"], "DownComponent"]

Out[7]=

Examine como o campo gravitacional difere do valor padrão de 9.81 sobre esta região.

In[8]:=

contourplot = ListContourPlot[data - Quantity[1, "StandardAccelerationOfGravity"], Frame -> False, PlotRangePadding -> 0, ColorFunction -> "SolarColors"]

Out[8]=

Sobreponha o gráfico de contorno sobre um mapa da China.

In[9]:=

Legended[GeoGraphics[{GeoStyling[{"GeoImage", contourplot}, Opacity[0.8]], Polygon[Entity["Country", "China"]]}, ImageSize -> 500, GeoRange -> Quantity[2200, "Kilometers"], GeoZoomLevel -> 5], BarLegend[{"SolarColors", MinMax@Flatten[QuantityMagnitude@data]}]]

Out[9]=