重力加速度の推定
重力加速度は，
を使って振り子の周期 
とその長さ 
を測ることで得ることができる．5回連続して周期を測定しその平均を出すことの不確実性はBatesDistributionでモデル化することができる．
In[1]:=
\[Mu]T = Quantity[2, "Seconds"]; \[CapitalDelta]T =
Quantity[0.01, "Seconds"];
period\[ScriptCapitalD] =
BatesDistribution[
5, {\[Mu]T - \[CapitalDelta]T/2, \[Mu]T + \[CapitalDelta]T/2}]Out[1]=
振り子の長さは解像度1mmの定規で計測されており，その不確実性はUniformDistributionでモデル化される．
In[2]:=
\[Mu]len = Quantity[1, "Meters"]; \[CapitalDelta]len =
UnitConvert[Quantity[1, "mm"], "Meters"];
len\[ScriptCapitalD] =
UniformDistribution[{\[Mu]len - \[CapitalDelta]len/
2., \[Mu]len + \[CapitalDelta]len/2.}]Out[2]=
重力加速度の計測における不確実性．
In[3]:=
g\[ScriptCapitalD] =
TransformedDistribution[ (2 \[Pi])^2 len/T^2, {len \[Distributed]
len\[ScriptCapitalD], T \[Distributed] period\[ScriptCapitalD]}]Out[3]=
線形近似と比較する．
In[4]:=
lin[e_, {x_, x0_}, {y_, y0_}] :=
Block[{f = Function @@ {{x, y}, e}}, f[x0, y0] +
\!\(\*SuperscriptBox[\(f\),
TagBox[
RowBox[{"(",
RowBox[{"1", ",", "0"}], ")"}],
Derivative],
MultilineFunction->None]\)[x0, y0] (x - x0) +
\!\(\*SuperscriptBox[\(f\),
TagBox[
RowBox[{"(",
RowBox[{"0", ",", "1"}], ")"}],
Derivative],
MultilineFunction->None]\)[x0, y0] (y - y0)]In[5]:=
lin\[ScriptCapitalD][\[ScriptCapitalD]_] :=
NormalDistribution[Mean[\[ScriptCapitalD]],
StandardDeviation[\[ScriptCapitalD]]]In[6]:=
gApprox\[ScriptCapitalD] =
TransformedDistribution[
lin[(2 Pi)^2 len/
T^2, {len, \[Mu]len}, {T, \[Mu]T}], {len \[Distributed]
lin\[ScriptCapitalD][len\[ScriptCapitalD]],
T \[Distributed] lin\[ScriptCapitalD][period\[ScriptCapitalD]]}]Out[6]=
厳密分布と線形分布を使って平均加速度を計算する．
In[7]:=
{\[Mu]g, \[Mu]gApprox} = {NExpectation[g,
g \[Distributed] g\[ScriptCapitalD]],
NExpectation[g, g \[Distributed] gApprox\[ScriptCapitalD]]}Out[7]=
不確実性尺度を計算する．
In[8]:=
{\[Sigma]g, \[Sigma]gApprox} = {Sqrt[
NExpectation[(g - \[Mu]g)^2, g \[Distributed] g\[ScriptCapitalD]]],
StandardDeviation[gApprox\[ScriptCapitalD]]}Out[8]=
測定加速度についての90%信頼区間のサンプリング推定を求める．
In[9]:=
confidenceInterval =
Quantile[RandomVariate[g\[ScriptCapitalD], 10^6], {0.05, 0.95}]Out[9]=
In[10]:=
NProbability[First[confidenceInterval] < x < Last[confidenceInterval],
x \[Distributed] g\[ScriptCapitalD]]Out[10]=
