Wolfram 언어

단위 및 날짜

중력 가속도의 추정

중력 가속도는 g=(2 pi)^2 l/T^2를 사용하여 진자의 주기 와 길이 를 측정함으로써 얻을 수있습니다. 5회 연속 주기 측정 후 그 평균을 낸 불확실성은 BatesDistribution에서 모델링 할 수있습니다.

In[1]:=
Click for copyable input
\[Mu]T = Quantity[2, "Seconds"]; \[CapitalDelta]T = Quantity[0.01, "Seconds"]; period\[ScriptCapitalD] = BatesDistribution[ 5, {\[Mu]T - \[CapitalDelta]T/2, \[Mu]T + \[CapitalDelta]T/2}]
Out[1]=

진자의 길이는 해상도 1mm의 자로 측정하였으며, 그 불확실성은 UniformDistribution으로 모델링됩니다.

In[2]:=
Click for copyable input
\[Mu]len = Quantity[1, "Meters"]; \[CapitalDelta]len = UnitConvert[Quantity[1, "mm"], "Meters"]; len\[ScriptCapitalD] = UniformDistribution[{\[Mu]len - \[CapitalDelta]len/ 2., \[Mu]len + \[CapitalDelta]len/2.}]
Out[2]=

중력 가속도 측정의 불확실성을 살펴봅니다.

In[3]:=
Click for copyable input
g\[ScriptCapitalD] = TransformedDistribution[ (2 \[Pi])^2 len/T^2, {len \[Distributed] len\[ScriptCapitalD], T \[Distributed] period\[ScriptCapitalD]}]
Out[3]=

선형 근사와 비교합니다.

In[4]:=
Click for copyable input
lin[e_, {x_, x0_}, {y_, y0_}] := Block[{f = Function @@ {{x, y}, e}}, f[x0, y0] + \!\(\*SuperscriptBox[\(f\), TagBox[ RowBox[{"(", RowBox[{"1", ",", "0"}], ")"}], Derivative], MultilineFunction->None]\)[x0, y0] (x - x0) + \!\(\*SuperscriptBox[\(f\), TagBox[ RowBox[{"(", RowBox[{"0", ",", "1"}], ")"}], Derivative], MultilineFunction->None]\)[x0, y0] (y - y0)]
In[5]:=
Click for copyable input
lin\[ScriptCapitalD][\[ScriptCapitalD]_] := NormalDistribution[Mean[\[ScriptCapitalD]], StandardDeviation[\[ScriptCapitalD]]]
In[6]:=
Click for copyable input
gApprox\[ScriptCapitalD] = TransformedDistribution[ lin[(2 Pi)^2 len/ T^2, {len, \[Mu]len}, {T, \[Mu]T}], {len \[Distributed] lin\[ScriptCapitalD][len\[ScriptCapitalD]], T \[Distributed] lin\[ScriptCapitalD][period\[ScriptCapitalD]]}]
Out[6]=

정확한 분포와 선형 분포를 사용하여 평균 가속도를 계산합니다.

In[7]:=
Click for copyable input
{\[Mu]g, \[Mu]gApprox} = {NExpectation[g, g \[Distributed] g\[ScriptCapitalD]], NExpectation[g, g \[Distributed] gApprox\[ScriptCapitalD]]}
Out[7]=

불확설성 척도를 계산합니다.

In[8]:=
Click for copyable input
{\[Sigma]g, \[Sigma]gApprox} = {Sqrt[ NExpectation[(g - \[Mu]g)^2, g \[Distributed] g\[ScriptCapitalD]]], StandardDeviation[gApprox\[ScriptCapitalD]]}
Out[8]=

측정 가속도에 대한 90% 신뢰 구간의 샘플링 추정을 구합니다.

In[9]:=
Click for copyable input
confidenceInterval = Quantile[RandomVariate[g\[ScriptCapitalD], 10^6], {0.05, 0.95}]
Out[9]=
In[10]:=
Click for copyable input
NProbability[First[confidenceInterval] < x < Last[confidenceInterval], x \[Distributed] g\[ScriptCapitalD]]
Out[10]=

관련 예제

de en es fr ja pt-br ru zh