Modélisation de phyllotaxie
L'angle doré est l'angle qui divise un angle 
complet en deux parties tel que donné par le rapport d'or.
Extrayez la valeur de l'angle doré.
In[1]:=
FunctionExpand[GoldenAngle]Out[1]=
Approximez la valeur en radians et en degrés.
In[2]:=
N@{GoldenAngle, GoldenAngle/Degree}Out[2]=
L'angle doré peut être utilisé pour modéliser les motifs de phyllotaxie.
Out[3]=
Définissez une fonction de phyllotaxie utilisant GoldenAngle.
In[4]:=
phyllotaxis[step_] :=
Table[Sqrt[i] AngleVector[i GoldenAngle], {i, 0, 1000, step}]Utilisez Graphics pour générer un motif de phyllotaxie à partir de ces points.
In[5]:=
Graphics[{PointSize[Medium], Point[phyllotaxis[1]]}]Out[5]=
Mettez en évidence des spirales de différentes étapes en utilisant différentes couleurs.
In[6]:=
Graphics[{PointSize[Medium], RGBColor[
0.2980392156862745, 0.28627450980392155`, 0.5490196078431373],
Point[phyllotaxis[1]], GrayLevel[1], Point[phyllotaxis[5]]}]Out[6]=
In[7]:=
Graphics[{PointSize[Medium], LCHColor[
Rational[1, 2],
Rational[1, 2],
Rational[1, 3]], Point[phyllotaxis[1]], CMYKColor[0, 0, 1, 0.05],
Point[phyllotaxis[7]]}]Out[7]=
Les motifs de phyllotaxie peuvent également être trouvés dans les têtes de tournesol.
Out[8]=
Définissez un motif.
In[9]:=
motif = FilledCurve@
BSplineCurve[4 {{0, -.75}, {0, .75}, {1, 0}, {1, 0}},
SplineClosed -> True];Visualisez-le.
In[10]:=
Graphics[motif]Out[10]=
Construisez une tête de tournesol de celui-ci.
In[11]:=
Graphics[{EdgeForm[
GrayLevel[1]],
Table[Rotate[Translate[motif, {Sqrt[i], 0}],
i GoldenAngle, {0, 0}], {i, 100, 0, -1}]}]Out[11]=
