Agrupación de audio usando características espectrales
Use características espectrales para encontrar agrupamientos en una lista de objetos de audio.
In[1]:=

a = ExampleData[{"Audio", "Drums"}, "Audio"]
Divida la grabación donde los transitorios ocurren.
In[2]:=

samples =
Select[AudioSplit[a,
FindPeaks[AudioLocalMeasurements[a, "Novelty"]]["Times"]],
Duration@# > Quantity[50, "ms"] &];
samples = Audio[#, Appearance -> "Minimal"] & /@ samples
Out[2]=

Represente gráficamente las muestras resultantes en posiciones definidas por su centroide y propagación espectral.
In[3]:=

ListPlot[Partition[
AudioMeasurements[#, {"SpectralCentroid", "SpectralSpread"},
"List"] & /@ samples, 1],
PlotMarkers -> (Audio[#, Appearance -> "Minimal"] & /@ samples),
AxesLabel -> {Style["Centroid", Italic], Style["Spread", Italic]},
ImageSize -> Medium]
Out[3]=

Encuentre sonidos similares usando las medidas "SpectralCentroid" y "SpectralSpread".
In[4]:=

FindClusters[
AudioMeasurements[#, {"SpectralCentroid", "SpectralSpread"},
"List"] & /@ samples -> samples]
Out[4]=
