¿Cuánto pesa?

El peso de un objeto en un campo gravitacional es el producto de su masa y el valor del campo gravitacional en el punto del objeto. En la superficie de la Tierra el campo gravitacional no es constante y, por lo tanto, el mismo objeto pesa distinto en distintas locaciones. Este ejemplo explora la variabilidad de la magnitud del campo gravitacional con elevación y latitud.

GeogravityModelData calcula varias propiedades del campo gravitacional de la Tierra en una ubicación dada.

In[1]:=

GeogravityModelData[GeoPosition[{0, 0}]]

Out[1]=

Esta utiliza elevación topográfica proporcionada por GeoElevationData.

In[2]:=

GeoElevationData[GeoPosition[{0, 0}]]

Out[2]=

Ignorando otros efectos, el campo gravitacional es generalmente más pequeño para una ubicación con latitud similar pero con mayor elevación.

In[3]:=

GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]]

Out[3]=

In[4]:=

GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]]; {GeoElevationData[%, UnitSystem -> "Metric"], GeogravityModelData[%, "Magnitude"]}

Out[4]=

Calcule los valores del campo gravitacional en puntos equidistantes en el ecuador.

In[5]:=

equatorialgravity = GeogravityModelData[{GeoPosition[{0, -180}], GeoPosition[{5, 180}]}, "Magnitude"][[1]]

Out[5]=

In[6]:=

ListPlot[equatorialgravity, Joined -> True]

Out[6]=

En el siguiente histograma, existen dos picos principales correspondientes a las áreas terrestres y al fondo de los océanos.

In[7]:=

Histogram[equatorialgravity, 20]

Out[7]=

Superponga la magnitud del campo gravitacional en un mapa de relieve de la Tierra.

In[8]:=

equatorialgravityplot = ListPlot[equatorialgravity, Axes -> False, Joined -> True, AspectRatio -> 1/8, PlotRangePadding -> None, ImagePadding -> None, ImageSize -> 400, PlotStyle -> Red];

In[9]:=

worldmap = GeoGraphics[GeoPath["Equator"], GeoRange -> "World", ImageSize -> 400, GeoBackground -> "ReliefMap"];

In[10]:=

Overlay[{worldmap, equatorialgravityplot}, Alignment -> Center]

Out[10]=

div>

Para mostrar la variabilidad de la latitud, promediamos la magnitud del campo gravitacional sobre la longitud, y representamos el resultado contra la latitud.

In[11]:=

gravity = Mean /@ GeogravityModelData[{GeoPosition[{-90, -180}], GeoPosition[{90, 180}]}, "Magnitude"];

La Antártida tiene un efecto obvio para las latitudes bajas, debido a la elevación agregada.

In[12]:=

ListPlot[gravity, DataRange -> {-90, 90}]

Out[12]=

In[13]:=

MinMax[gravity]

Out[13]=

Por lo tanto, pueden haber cambios en el orden de 0.5% en el peso de un objeto dado, dependiendo de donde lo midamos.

In[14]:=

MinMax[gravity]; 1 - First[%]/Last[%]