Mercator esférico o elipsoidal
La proyección de Mercator produce distintos resultados con un modelo esférico de la Tierra, que con uno elipsoidal. Wolfram Language le permite trabajar con ambas situaciones.
La proyección utilizada en la mayoría de servidores web de mapas utiliza un modelo esférico de la Tierra y, por lo general, se llama "web Mercator".
In[1]:=
webMercator = {"Mercator",
"ReferenceModel" -> GeodesyData["WGS84", "SemimajorAxis"]}Out[1]=
In[2]:=
ellipMercator = {"Mercator", "ReferenceModel" -> "WGS84"}Out[2]=
Transforme la ubicación de la Universidad de Oxford usando ambas proyecciones.
In[3]:=
p = GeoPosition[
Entity["University", "UniversityOfOxfordUnitedKingdom36022"]]Out[3]=
In[4]:=
GeoGridPosition[p, webMercator][[1]]Out[4]=
In[5]:=
GeoGridPosition[p, ellipMercator][[1]]Out[5]=
Existe una diferencia vertical correspondiente a más de 33 kilómetros en las coordenadas hacia el norte.
In[6]:=
GeoGridPosition[p, webMercator][[1]];
GeoGridPosition[p, ellipMercator][[1]];
%% - %Out[6]=
Por ejemplo, trace los respectivos mapas del Reino Unido e Irlanda, los cuales parecen casi idénticos.
In[7]:=
webmap = GeoGraphics[{FaceForm[], EdgeForm[Red],
Polygon[{Entity["Country", "UnitedKingdom"],
Entity["Country", "Ireland"]}], Red, Point[p]},
GeoProjection -> webMercator, GeoBackground -> None][[1]]Out[7]=
In[8]:=
ellipmap =
GeoGraphics[{FaceForm[], EdgeForm[Blue],
Polygon[{Entity["Country", "UnitedKingdom"],
Entity["Country", "Ireland"]}], Blue, Point[p]},
GeoProjection -> ellipMercator, GeoBackground -> None][[1]]Out[8]=
Sin embargo, cuando se superponen en el mismo mapa, podemos ver claramente la diferencia.
In[9]:=
Show[webmap, ellipmap]Out[9]=
