球形或椭球形麦卡托
麦卡托投影对于球形和椭球形地球模型产生出不同结果. Wolfram 语言让你对两种情况都能够进行操作.
在大多数网页服务中使用的地球的球形投影，通常被称为“网页麦卡托”.
In[1]:=
webMercator = {"Mercator",
"ReferenceModel" -> GeodesyData["WGS84", "SemimajorAxis"]}Out[1]=
In[2]:=
ellipMercator = {"Mercator", "ReferenceModel" -> "WGS84"}Out[2]=
用两种投影对牛津大学的位置进行变换.
In[3]:=
p = GeoPosition[
Entity["University", "UniversityOfOxfordUnitedKingdom36022"]]Out[3]=
In[4]:=
GeoGridPosition[p, webMercator][[1]]Out[4]=
In[5]:=
GeoGridPosition[p, ellipMercator][[1]]Out[5]=
北向坐标有一个相应的 33 公里多的差别.
In[6]:=
GeoGridPosition[p, webMercator][[1]];
GeoGridPosition[p, ellipMercator][[1]];
%% - %Out[6]=
用两种方法，分别绘制英国和爱尔兰的地图，其结果看上去几乎一致.
In[7]:=
webmap = GeoGraphics[{FaceForm[], EdgeForm[Red],
Polygon[{Entity["Country", "UnitedKingdom"],
Entity["Country", "Ireland"]}], Red, Point[p]},
GeoProjection -> webMercator, GeoBackground -> None][[1]]Out[7]=
In[8]:=
ellipmap =
GeoGraphics[{FaceForm[], EdgeForm[Blue],
Polygon[{Entity["Country", "UnitedKingdom"],
Entity["Country", "Ireland"]}], Blue, Point[p]},
GeoProjection -> ellipMercator, GeoBackground -> None][[1]]Out[8]=
但是，当我们将同样的地图重叠在一起，就可以清楚地看出区别.
In[9]:=
Show[webmap, ellipmap]Out[9]=
