Wolfram Language™

Trace um passeio a pé de edifícios famosos

Use GeoNearest para extrair edifícios famosos em um raio de 1 km ao redor da prefeitura de Boston.

In[1]:=

position = Entity["Building", "BostonCityHall::96t3t"]; radius = Quantity[1, "Kilometers"];

In[2]:=

nearMe = GeoNearest["Building", position, {All, radius}]

Out[2]=

Faça uma representaçãp gráfica desses edifícios em um mapa local, usando os ícones de entidades integrados.

In[3]:=

iconItemPairs = With[{icon = EntityValue[Entity["Icon", "Museum"], "Image"][[1]]}, MapThread[{#1, Graphics[{EdgeForm[Black], FaceForm[#2], icon}, "ImageSize" -> 25]} &, {nearMe, RandomColor[Length@nearMe]}] ]; legend = Column[ Row[Reverse@#] & /@ (MapAt[CommonName, #, 1] & /@ iconItemPairs)]; Row[{ GeoGraphics[{EdgeForm[Darker[Orange]], Orange, GeoDisk[position, radius], GeoMarker[position, "Color" -> Red], GeoMarker @@@ iconItemPairs}, ImageSize -> 400], legend }]

Out[3]=

Use TravelDirectionspara calcular um passeio a pé por essas entidades.

In[4]:=

tourPlaces = Prepend[nearMe, position];

In[5]:=

{distance, tourPath} = FindShortestTour[GeoPosition /@ tourPlaces, 1, Length@tourPlaces]

Out[5]=

In[6]:=

travelDirectionsForPath = TravelDirections[tourPlaces[[tourPath]], TravelMethod -> "Walking"]

Out[6]=

In[7]:=

Row[{ GeoGraphics[{ Thickness[0.01], Darker@Red, GeoPath@travelDirectionsForPath, EdgeForm[Darker[Orange]], Orange, GeoDisk[position, radius], GeoMarker[position, "Color" -> Red], GeoMarker @@@ iconItemPairs }, ImageSize -> 400], legend }]

Out[7]=

Estas são instruções detalhadas sobre como fazer a rota.

In[8]:=

travelDirectionsForPath["ManeuverGrid"]

Out[8]=