Einen Spaziergang zu bemerkenswerten Bauwerken generieren: Neu in Wolfram Language 11

Einen Spaziergang zu bemerkenswerten Bauwerken generieren

Ermitteln Sie mit GeoNearest bemerkenswerte Bauwerke im Radius von 1 km rund um die Boston City Hall.

In[1]:=

position = Entity["Building", "BostonCityHall::96t3t"];
radius = Quantity[1, "Kilometers"];

In[2]:=

nearMe = GeoNearest["Building", position, {All, radius}]

Out[2]=

Plotten Sie dies Gebäude auf einem Stadtplan mithilfe eingebauter Icon-Entitäten.

Den kompletten Wolfram Language-Input zeigen

In[3]:=

iconItemPairs = 
  With[{icon = EntityValue[Entity["Icon", "Museum"], "Image"][[1]]},
   MapThread[{#1, 
      Graphics[{EdgeForm[Black], FaceForm[#2], icon}, 
       "ImageSize" -> 25]} &, {nearMe, RandomColor[Length@nearMe]}]
   ];
legend = Column[
   Row[Reverse@#] & /@ (MapAt[CommonName, #, 1] & /@ iconItemPairs)];
Row[{
  GeoGraphics[{EdgeForm[Darker[Orange]], Orange, 
    GeoDisk[position, radius], GeoMarker[position, "Color" -> Red], 
    GeoMarker @@@ iconItemPairs}, ImageSize -> 400],
  legend
  }]

Out[3]=

Berechnen Sie mit TravelDirections einen Rundgang zu diesen Entitäten.

In[4]:=

tourPlaces = Prepend[nearMe, position];

In[5]:=

{distance, tourPath} = 
 FindShortestTour[GeoPosition /@ tourPlaces, 1, Length@tourPlaces]

Out[5]=

In[6]:=

travelDirectionsForPath = 
 TravelDirections[tourPlaces[[tourPath]], TravelMethod -> "Walking"]

Out[6]=

Den kompletten Wolfram Language-Input zeigen

In[7]:=

Row[{
  GeoGraphics[{
    Thickness[0.01], Darker@Red, GeoPath@travelDirectionsForPath,
    EdgeForm[Darker[Orange]], Orange, GeoDisk[position, radius],
    GeoMarker[position, "Color" -> Red], GeoMarker @@@ iconItemPairs
    }, ImageSize -> 400],
  legend
  }]

Out[7]=

Das sind die detaillierten Richtungsangaben, denen Sie für diesen Rundgang folgen sollten.

In[8]:=

travelDirectionsForPath["ManeuverGrid"]

Out[8]=

Wolfram Language™

Einen Spaziergang zu bemerkenswerten Bauwerken generieren

Verwandte Beispiele