Visualize e analise estruturas anatômicas: Novos Recursos do Wolfram Language 11

Visualize e analise estruturas anatômicas

Faça uma representação gráfica da estrutura óssea e a pele do pé humano e estime sua área de superfície (em milímetros quadrados).

In[1]:=

Row[EntityValue[{Entity["AnatomicalStructure", "RightFoot"], 
   Entity["AnatomicalStructure", "SkinOfRightFoot"]}, "MeshRegion"]]

Out[1]=

In[2]:=

Area[EntityValue[Entity["AnatomicalStructure", "SkinOfRightFoot"], 
  "MeshRegion"]]

Out[2]=

Faça uma representação gráfica da conectividade dos ramos distais da artéria braquial.

In[3]:=

NestGraph[Cases[EntityValue[#, "Branches"], _Entity] &, 
 Entity["AnatomicalStructure", "BrachialArtery"], 3, 
 VertexLabels -> Placed["Name", Tooltip], EdgeStyle -> Pink, 
 VertexStyle -> Pink, GraphStyle -> "BasicBlack"]

Out[3]=

Encontre as partes do antebraço esquerdo.

In[4]:=

g = NestGraph[Cases[EntityValue[#, "ConstitutionalParts"], _Entity] &,
   Entity["AnatomicalStructure", "LeftForearm"], 2]

Out[4]=

Calcule o comprimento combinado da faringe, esôfago, estômago, intestino delgado, e intestino grosso.

In[5]:=

UnitConvert[
 EntityValue[
  EntityGroup[{Entity["AnatomicalStructure", "Pharynx"], 
    Entity["AnatomicalStructure", "Esophagus"], 
    Entity["AnatomicalStructure", "Stomach"], 
    Entity["AnatomicalStructure", "SmallIntestine"], 
    Entity["AnatomicalStructure", "LargeIntestine"]}], 
  "Length"], "Metric"]

Out[5]=

Compare o comprimento e a largura do pé de homens e mulheres.

In[6]:=

# -> (UnitConvert[#, "Centimeters"] & /@ 
     EntityValue[
      EntityInstance[Entity["AnatomicalStructure", "Foot"], 
       "Gender" -> #], {"Length", "Width"}, 
      "PropertyAssociation"]) & /@ {"Female", "Male"}

Out[6]=

Wolfram Language™

Visualize e analise estruturas anatômicas

Exemplos Relacionados