Visualisez et analysez les structures anatomiques : Nouveautés de Wolfram Language 11

Visualisez et analysez les structures anatomiques

Tracez la structure osseuse et la peau d'un pied humain et calculez sa surface (en millimètres carrés).

In[1]:=

Row[EntityValue[{Entity["AnatomicalStructure", "RightFoot"], 
   Entity["AnatomicalStructure", "SkinOfRightFoot"]}, "MeshRegion"]]

Out[1]=

In[2]:=

Area[EntityValue[Entity["AnatomicalStructure", "SkinOfRightFoot"], 
  "MeshRegion"]]

Out[2]=

Tracez la connectivité des branches distales de l'artère brachiale.

In[3]:=

NestGraph[Cases[EntityValue[#, "Branches"], _Entity] &, 
 Entity["AnatomicalStructure", "BrachialArtery"], 3, 
 VertexLabels -> Placed["Name", Tooltip], EdgeStyle -> Pink, 
 VertexStyle -> Pink, GraphStyle -> "BasicBlack"]

Out[3]=

Trouvez les parties de l'avant-bras gauche.

In[4]:=

g = NestGraph[Cases[EntityValue[#, "ConstitutionalParts"], _Entity] &,
   Entity["AnatomicalStructure", "LeftForearm"], 2]

Out[4]=

Calculez la longueur combinée du pharynx, de l'œsophage, de l'estomac, de l'intestin grêle et du gros intestin.

In[5]:=

UnitConvert[
 EntityValue[
  EntityGroup[{Entity["AnatomicalStructure", "Pharynx"], 
    Entity["AnatomicalStructure", "Esophagus"], 
    Entity["AnatomicalStructure", "Stomach"], 
    Entity["AnatomicalStructure", "SmallIntestine"], 
    Entity["AnatomicalStructure", "LargeIntestine"]}], 
  "Length"], "Metric"]

Out[5]=

Comparez la longueur et la largeur du pied chez les hommes et les femmes.

In[6]:=

# -> (UnitConvert[#, "Centimeters"] & /@ 
     EntityValue[
      EntityInstance[Entity["AnatomicalStructure", "Foot"], 
       "Gender" -> #], {"Length", "Width"}, 
      "PropertyAssociation"]) & /@ {"Female", "Male"}

Out[6]=