Wolfram Language™

Parametrisierung einer Mannigfaltigkeit

Verwenden Sie für die Parametrisierung einer Mannigfaltigkeit einen Autoencoder, also ein Netz mit einer „Bottleneck“-Schicht, das lernt, den ursprünglichen Input zu rekonstruieren.

Beziehen Sie Trainingsdaten aus einem Teil einer synthetischen zweidimensionalen Mannigfaltigkeit.

In[1]:=

manifold = Table[AngleVector[{x, 0.9 Pi x}] + x/20*RandomVariate[NormalDistribution[], 2], {x, 0, 1, 0.001}]; plot = ListPlot[manifold, PlotStyle -> Orange]

Out[1]=

Erzeugen Sie ein Netz mit einer „Bottleneck“-Schicht, um die Parametrisierung einer Mannigfaltigkeit zu erlernen.

In[2]:=

net = NetChain[{25, Ramp, 1, 25, Ramp, 2}, "Input" -> 2]

Out[2]=

Erzeugen Sie ein Verlustnetz, das einen Verlust basierend auf dem „Rekonstruktionsfehler“ berechnet – ein Bewertung der Fähigkeit des Netzes, einen Output zu produzieren, der identisch mit dem Input ist.

In[3]:=

lossNet = NetGraph[{net, MeanSquaredLossLayer[]}, {1 -> 2, NetPort["Input"] -> NetPort[2, "Target"]}]

Out[3]=

Trainieren Sie das Verlustnetz mit der Mannigfaltigkeit und extrahieren Sie das Originalnetz aus dem Verlustnetz.

In[4]:=

lossNet = NetTrain[lossNet, <|"Input" -> manifold|>, BatchSize -> 4096]; trained = NetExtract[lossNet, 1];

Visualisieren Sie, wie das Netz beliebige Punkte auf die Mannigfaltigkeit projiziert.

In[5]:=

{{xmin, xmax}, {ymin, ymax}} = CoordinateBounds[manifold, .2]; Show[plot, StreamPlot[ trained[{x, y}] - {x, y}, {x, xmin, xmax}, {y, ymin, ymax}]]

Out[5]=

Teilen Sie das Netz in ein „Encoder“- und ein „Decoder“-Netz (der Encoder parametrisiert Punkte mit einem einzigen Skalarwert, während der Decoder die Punkte aus dieser Parametrisierung rekonstruiert).

In[6]:=

decoder = Drop[trained, 3] encoder = Take[trained, 3]

Out[6]=

Out[6]=

Färben Sie jeden Punkt in der originalen Mannigfaltigkeit nach deren Encoder-Parametrisierung.

In[7]:=

ListPlot[Style[#, Hue[First[0.3 + encoder[#]]/3]] & /@ manifold]

Out[7]=

Ermitteln Sie den Parametrisierungsbereich, indem Sie den Encoder auf die Mannigfaltigkeit anwenden.

In[8]:=

{min, max} = MinMax[encoder[manifold]]

Out[8]=

Zeigen Sie die Rekonstruktion über diesem Bereich gemeinsam mit der originalen Mannigfaltigkeit.

In[9]:=

Show[plot, ListLinePlot[Table[decoder[x], {x, min, max, .01}]]]

Out[9]=