Medición del rendimiento de la clasificación
Mida la precisión de un reconocedor de dígitos entrenado con la base de datos de dígitos de escritura a mano MNIST.
Primero obtenga los datos de entrenamiento y validación.
In[1]:=
resource = ResourceObject["MNIST"];
trainingData = ResourceData[resource, "TrainingData"];
testData = ResourceData[resource, "TestData"];In[2]:=
RandomSample[trainingData, 5]Out[2]=
Defina una red neuronal de convolución que toma imágenes con escala de grises 28x28 como entrada.
In[3]:=
lenet = NetChain[{
ConvolutionLayer[20, 5], Ramp,
PoolingLayer[2, 2],
ConvolutionLayer[50, 5], Ramp,
PoolingLayer[2, 2],
FlattenLayer[],
500, Ramp, 10,
SoftmaxLayer[]},
"Output" -> NetDecoder[{"Class", Range[0, 9]}],
"Input" -> NetEncoder[{"Image", {28, 28}, "Grayscale"}]
]Out[3]=
Entrene la red para tres rondas de entrenamiento.
In[4]:=
lenet = NetTrain[lenet, trainingData, ValidationSet -> testData,
MaxTrainingRounds -> 3]Out[4]=
Evalúe la red entrenada directamente en imágenes al azar del conjunto de validación.
In[5]:=
imgs = Keys @ RandomSample[testData, 5];
Thread[imgs -> lenet[imgs]]Out[5]=
Cree un objeto de ClassifierMeasurements a partir de la red entrenada y el conjunto de validación.
In[6]:=
cm = ClassifierMeasurements[lenet, testData]Out[6]=
Obtenga la precisión de la red en el conjunto de validación.
In[7]:=
cm["Accuracy"]Out[7]=
Cree una lista de 3 que fueron erróneamente clasificados con 8.
In[8]:=
cm[{"Examples", 3 -> 8}]Out[8]=
Obtenga un gráfico de la matriz de confusión de las predicciones de la red en el conjunto de validación.
In[9]:=
cm["ConfusionMatrixPlot"]Out[9]=
