Язык Wolfram Language™

Ядерные реакторы в современном мире

NuclearReactorData предоставляет данные об известных ядерных реакторах по всему миру. Некоторые из них, например Чернобыль, уже закрыты. Выберем реакторы, функционирующие в настоящее время, для анализа ядерных энергетических ресурсов.

In[1]:=

reactors = NuclearReactorData[];

In[2]:=

active = Keys@ Select[EntityValue["NuclearReactor", "Status", "EntityAssociation"], # === "operational" &];

Извлечем информацию о годовом объеме производства энергии для отдельных стран.

In[3]:=

annualproduction = NuclearReactorData[active, "AnnualEnergyProduction"]; countries = Map[First, NuclearReactorData[active, "Countries"]];

Создадим базу данных и удалим пропущенные значения. В современном мире свыше 400 работающих ядерных реакторов.

In[4]:=

data = Transpose[{active, countries, annualproduction}]; data = DeleteMissing[data, 1, 2];

In[5]:=

data // Dimensions

Out[5]=

Рассчитаем количество ядерных реакторов на страну.

In[6]:=

percountry = GroupBy[data, #1[[2]] &];

In[7]:=

numberpercountry = Map[Length, percountry];

In[8]:=

BarChart[Sort[numberpercountry], ChartLabels -> Automatic, ChartStyle -> "DarkRainbow", BarOrigin -> Left, BarSpacing -> 1, LabelingFunction -> (Placed[#1, After] &), ImageSize -> Large]

Out[8]=

Число реакторов соответствует общему объёму ядерной энергии, производимой в данной стране.

In[9]:=

energytotals = Map[Total[#[[All, 3]]] &, percountry];

In[10]:=

stats = {Min, Max, Mean, Median, Total}; TableForm[#[energytotals] & /@ stats, TableHeadings -> {stats}]

Out[10]//TableForm=

Крупнейшими производителями атомной энергии являются Соединенные Штаты и Франция.

In[11]:=

TakeLargest[energytotals, 2]

Out[11]=

In[12]:=

GeoRegionValuePlot[energytotals, GeoProjection -> "Mercator", GeoRange -> {{-70, 80}, {-170, 190}}, GeoLabels -> (Tooltip[#1, #2] &)]

Out[12]=

Ситуация меняется, если учесть общий объем производства энергии на душу населения. Функция CountryData сообщает размер населения для каждой страны в списке.

In[13]:=

populations = AssociationThread[Keys[energytotals], CountryData[#, "Population"] & /@ Keys[energytotals]];

Рассчитаем потребление ядерной энергии на душу населения.

In[14]:=

energypercapita = energytotals/populations;

In[15]:=

TableForm[#[energypercapita] & /@ stats, TableHeadings -> {stats}]

Out[15]//TableForm=

Полученная карта показывает, что даже при том, что США имеет самое крупное производство ядерной энергии в мире, Франция и Швеция лидируют по потреблению ядерной энергии на душу населения.

In[16]:=

TakeLargest[energypercapita, 2]

Out[16]=

In[17]:=

GeoRegionValuePlot[energypercapita, GeoProjection -> "Mercator", GeoRange -> {{-70, 80}, {-170, 190}}, GeoLabels -> (Tooltip[#1, #2] &)]

Out[17]=