Generación de cuestionarios en línea: Nuevo en Wolfram Language 11

Generación de cuestionarios en línea

Es fácil crear e implementar formularios usando la nueva funcionalidad incorporada. Tales formularios pueden ser implementados en la nube, proporcionando almacenaje persistente fluido de código y datos, computación en la nube, e implementación externa instantánea por medio de documentos activos, API, aplicaciones, etc. Estos atributos son ilustrados aquí por medio de la creación e implementación de dos "cuestionarios" que indagan al usuario para identificar grandes ciudades y ciertas películas populares, respectivamente.

Cree un cuestionario sobre grandes ciudades en los EE.UU. en la nube.

In[1]:=

CloudDeploy[
 FormFunction[{"city", 
    "How many of the 10 most populous US cities can you name?"} -> 
   RepeatingElement[
    Restricted[
     "City", {"Country" -> Entity["Country", "UnitedStates"], 
      "Population" -> TakeLargest[10]}], {1, {1, 10}}], 
  GeoListPlot[{#city, 
     Complement[
      EntityList@
       Entity["City", {"Country" -> Entity["Country", "UnitedStates"],
          "Population" -> TakeLargest[10]}], #city]}, 
    GeoLabels -> True, PlotLegends -> {"OK", "Missed"}] &, "PNG"]]

Out[1]=

Visite el formulario para interactuar con él.

Si uno de los espacios no corresponde a una de las 10 ciudades más grandes de EE.UU., el formulario desplegará un mensaje de error.

Cree un cuestionario en la nube sobre películas.

In[2]:=

CloudDeploy[
 FormFunction[{"movies", 
    "How many of the 10 top grossing movies by Steven Spielberg can \
you name?"} -> 
   RepeatingElement[
    Restricted[
     "Movie", {"Director" -> 
       Entity["Person", "StevenSpielberg::76z25"],
      "DomesticBoxOfficeGross" -> TakeLargest[10]}], {1, {1, 10}}],
  With[{images = 
      EntityValue[
       EntityClass[
        "Movie", {"Director" -> 
          Entity["Person", "StevenSpielberg::76z25"],
         "DomesticBoxOfficeGross" -> TakeLargest[10]}], "Image", 
       "EntityAssociation"]},
    Grid[{
      {"you guessed", Length[#movies], 
       ImageCollage[Values[KeyTake[images, #movies]]]}, {"you missed",
        10 - Length[#movies], 
       ImageCollage[Values[KeyDrop[images, #movies]]]}
      }, Frame -> All, Alignment -> Left]] &]]

Out[2]=