Wolfram Language™

Yoga para la salud y el conocimiento

Wolfram Knowledgebase incluye un conjunto de datos de posturas de yoga. Como resultado, las relaciones entre las posturas, sus niveles de dificultad, los músculos que involucran, sus duraciones, y muchas otras características pueden ser exploradas y estudiadas de forma programática precisa, simple y potente.

Forme y visualice las relaciones entre posturas de yoga con base en las relaciones de "PreparatoryPoses", comenzando con la postura del escorpión.

In[1]:=

poseGraph = NestGraph[Cases[EntityValue[#, "PreparatoryPoses"], _Entity] &, Entity["YogaPose", "ScorpionPose"], 4, VertexLabels -> "Name", VertexLabelStyle -> LightGray]

Out[1]=

Muestre imágenes esquemáticas de varias posturas.

In[2]:=

With[{v = Take[VertexList[poseGraph], 5]}, schm = Rule @@@ Transpose[{v, EntityValue[v, "Schematic"]}] ] // Column

Out[2]=

Cree un gráfico de posturas agrupadas por "comunidades" que comparten vínculos.

In[3]:=

CommunityGraphPlot[EdgeList[poseGraph] /. e_DirectedEdge :> Reverse@e, VertexLabels -> Placed["Name", Tooltip]]

Out[3]=

Cuente el número de músculos contraídos en la serie de poses en una secuencia primaria de Ashtanga yoga y grafíquelos frente al número de músculos que participan.

In[4]:=

mus = Normal[ EntityValue[ Cases[Entity["YogaSequence", "AshtangaPrimarySeries"][ "PrimaryPoseSequence"] /. Entity["YogaSequence", s_] :> Entity["YogaSequence", s]["PrimaryPoseSequence"], _Entity, Infinity], "PrimaryContractedMuscles", "EntityAssociation"]] /. Rule[l_, r_] :> l -> Length[r];

In[5]:=

ListLinePlot[mus[[All, -1]], Filling -> Axis, AspectRatio -> .4, AxesLabel -> {"pose position", "contracted muscles count"}]

Out[5]=

Encuentre los músculos que son estirados en la serie de posturas en el saludo al Sol A y visualice los músculos estirados con mayor frecuencia.

In[6]:=

muscles = (SortBy[ Tally[DeleteMissing[ Flatten[EntityValue[ Cases[Entity["YogaSequence", "SunSalutationA"][ "PrimaryPoseSequence"], _Entity, Infinity], "StretchedMuscles"]]]], Last] // Reverse) // Take[#, 20] &

Out[6]=

Visualice el músculo estirado con mayor frecuencia.

In[7]:=

EntityValue[muscles[[1, 1]], "RegionalLocationImage"]

Out[7]=

Use una clase de entidades implícitamente definida y visualice posturas de yoga de nivel principiante e intermedio que estire la pierna y fortalezca la sección abdominal.

In[8]:=

EntityList[ Entity["YogaPose", {"ExperienceLevel" -> "Beginner", "IntensityLevel" -> "Medium", "SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"], "SitesOfImprovedStrength" -> Entity["AnatomicalStructure", "Abdomen"]}]]

Out[8]=

Vea imágenes esquemáticas de estas posturas como una asociación de entidades.

In[9]:=

EntityList[ Entity["YogaPose", {"ExperienceLevel" -> "Beginner", "IntensityLevel" -> "Medium", "SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"], "SitesOfImprovedStrength" -> Entity["AnatomicalStructure", "Abdomen"]}]]; EntityValue[Take[%, 5], "Schematic", "EntityAssociation"]

Out[9]=

Muestre las posturas avanzadas de yoga que fortalecen los iliopsoas y estiren los músculos isquiotibiales.

In[10]:=

EntityValue[ Entity["YogaPose", {"ExperienceLevel" -> "Advanced", "PrimaryContractedMuscles" -> Entity["AnatomicalStructure", "Iliopsoas"], "StretchedMuscles" -> Entity["AnatomicalStructure", "SetOfHamstringMuscles"]}], "Schematic", "EntityAssociation"]

Out[10]=

Encuentre secuencias de yoga con duraciones entre 30 y 60 minutos.

In[11]:=

EntityList@ Entity["YogaSequence", {"EstimatedDuration" -> Quantity[ Interval[{30, 60}], "Minutes"]}]

Out[11]=