Wolfram Language™

Autoanálisis de Wolfram Language

Wolfram Knowledgebase contiene no sólo información acerca de entidades externas, sino también particulares acerca de Wolfram Language mismo. Este conocimiento puede ser utilizado para explorar la estructura (y evolución) del lenguaje. También puede ayudar en el descubrimiento de funcionalidades de interés. Aquí, las clases de entidades implícitamente definidas son utilizadas para identificar símbolos de Wolfram Language que satisfacen ciertos criterios de interés.

Use una clase implícitamente definida para identificar símbolos introducidos en la versión 11.

In[1]:=

EntityList[ EntityClass["WolframLanguageSymbol", "VersionIntroduced" -> 11]] // Take[#, 20] &

Out[1]=

Extraiga símbolos agregados en la versión 10 y modificados en la versión 11.

In[2]:=

EntityList[EntityClass["WolframLanguageSymbol", {"VersionIntroduced" -> Interval[{10, 10.4}], "VersionsModified" -> ContainsAny[{11}]}]]

Out[2]=

Encuentre símbolos llamados en honor a Carl Friedrich Gauss.

In[3]:=

EntityList[ EntityClass[ "WolframLanguageSymbol", {"EponymousPeople" -> ContainsAny[{Entity["Person", "CarlFriedrichGauss::4vctc"]}]}]]

Out[3]=

Encuentre símbolos de gráficos introducidos en las versiones de Mathematica de la 8 a la 11.

In[4]:=

EntityList[EntityClass["WolframLanguageSymbol", { "FunctionalityAreas" -> ContainsAny[{"GraphicsPrimitiveSymbols"}], "VersionIntroduced" -> Interval[{8, 11}] }]]

Out[4]=

Encuentre los 10 símbolos más utilizados (en todos los corpora) usando un calificador EntityProperty combinado con una clase de entidades implícitamente definidas.

In[5]:=

EntityClass["WolframLanguageSymbol", EntityProperty["WolframLanguageSymbol", "Frequencies", {"Corpus" -> "All"}] -> TakeLargest[10]]

Out[5]=

Vea los contenidos de la resultante clase de entidades implícita haciendo clic en [+].

Out[6]=

Resuelva la clase de entidades en miembros constituyentes usando EntityList.

In[7]:=

EntityClass["WolframLanguageSymbol", EntityProperty["WolframLanguageSymbol", "Frequencies", {"Corpus" -> "All"}] -> TakeLargest[10]]; EntityList[%]

Out[7]=

Extraiga las frecuencias de uso.

In[8]:=

EntityList[ EntityClass["WolframLanguageSymbol", "VersionIntroduced" -> 11]] // Take[#, 20] &; EntityList[%]; top10 = EntityValue[%, EntityProperty["WolframLanguageSymbol", "Frequencies", {"Corpus" -> "All"}], "EntityAssociation"]

Out[8]=

Cree un gráfico circular de frecuencias de uso de esos símbolos.

In[9]:=

PieChart[ Append[top10, "others" -> 1 - Total[Values[top10]]], LabelingFunction -> Function[Row[{NumberForm[100 #, {3, 1}], "%"}]], ChartLegends -> Automatic, ChartStyle -> "Rainbow"]

Out[9]=