Visualisez the Wolfram Language

La structure de Wolfram Language et ses relations avec la base de connaissances de Wolfram peuvent être visualisées de plusieurs façons intéressantes. Dans cet exemple, vous pouvez créer un nuage de mots encapsulant des aspects de cette relation, explorer et assembler de manière computationnelle des exemples de sorties de la documentation, et visualiser les lieux et les époques associés aux personnes dont les noms apparaissent dans les symboles de Wolfram Language.

Créez un nuage de mots à partir des termes apparaissant dans la documentation WolframLanguageData.

In[1]:=

WordCloud[ DeleteStopwords[ Flatten[TextWords[ WolframLanguageData["WolframLanguageData", "TextStrings"]]]]]

Out[1]=

Créez un collage des sorties de l'exemple de documentation de base pour Plot.

In[2]:=

ImageCollage[ Cases[WolframLanguageData["Plot", "DocumentationBasicExamples"], c : Cell[_, "Output", ___] :> Rasterize[RawBoxes[c]], \[Infinity]], ImagePadding -> 10, Background -> Transparent]

Out[2]=

Créez un collage de tous les graphiques de sortie de l'exemple de documentation pour Plot.

In[3]:=

evaluate[l_List] := Module[{p}, p = l /. RawBoxes[Cell[BoxData[wlc_], "Input", ___]] :> ToExpression[wlc, StandardForm, Hold]; Block[Evaluate[ Select[Union[Cases[p, _Symbol, {-1}]], Quiet[Context[#] === "Global`"] &]], ReleaseHold /@ p]]

In[4]:=

ImageCollage[ Rasterize[#, ImageSize -> 100] & /@ Cases[Flatten[ evaluate /@ Flatten[WolframLanguageData["Plot", "DocumentationExampleInputs"][[All, -1]], 1]], _Graphics], ImagePadding -> 2] // Quiet

Out[4]=

Affichez les images des personnes associées au symbole LaplacianGaussianFilter en Wolfram Language.

In[5]:=

ImageAssemble[ PersonData[ WolframLanguageData["LaplacianGaussianFilter", "EponymousPeople"], "Image"]]

Out[5]=

Extrayez les personnes qui ont donné leur nom aux symboles de Wolfram Language.

In[6]:=

people = DeleteCases[ Union[Flatten[ WolframLanguageData[All, "EponymousPeople"]]], _Missing];

Obtain information on their birthplaces.

In[7]:=

placedata = DeleteCases[ PersonData[ people, {"Image", "BirthPlace", "Name"}], {_, _Missing, _}];

Visualisez ces lieux et les personnes qui y sont associées sur une carte du monde.

In[8]:=

GeoGraphics[ Tooltip[Point[#2], Column[DeleteCases[{##} /. e_Entity :> CommonName[e], _Missing]]] & @@@ placedata] // Quiet

Out[8]=

Extrayez les dates de naissance et de décès des personnes qui ont donné leur nom aux symboles de Wolfram Language.

In[9]:=

timedata = Block[{EntityFramework`$EntityValueBatchSize = 300}, DeleteCases[ PersonData[ people, {"BirthDate", "DeathDate", "Name", "Image"}], {_Missing, __}]];

Créez un tracé chronologique.

In[10]:=

formatdates[d1_, d2_] := Row[Riffle[Switch[#, Missing["Alive"], "present", _Missing, "????", _, DateString[#, {"MonthName", " ", "DayShort", ", ", "Year"}] ] & /@ {d1, d2}, "-"]]

In[11]:=

TimelinePlot[ Association @@ ((Tooltip[StringSplit[#3, " "][[-1]], Column[{#4, #3, formatdates[#1, #2]}]] -> #1) & @@@ Select[timedata, #[[1]] > DateObject[{1800}] &])]

Out[11]=