Wolfram Language™

Visualize a Wolfram Language

A estrutura da Wolfram Language e suas relações com a Wolfram Knowledgebase podem ser visualizadas de várias maneiras interessantes. Neste exemplo, você pode fazer uma nuvem de palavras envolvendo os aspectos desta relação, explore de forma computacional e monte exemplo de resultados de documentação, e visualize os lugares e tempos associados com as pessoas cujos nomes aparecem como parte de símbolos da Wolfram Language.

Crie uma nuvem de palavras de termos existentes na documentação de WolframLanguageData.

In[1]:=

WordCloud[ DeleteStopwords[ Flatten[TextWords[ WolframLanguageData["WolframLanguageData", "TextStrings"]]]]]

Out[1]=

Crie uma colagem de resultados de exemplo de documetação básica de Plot.

In[2]:=

ImageCollage[ Cases[WolframLanguageData["Plot", "DocumentationBasicExamples"], c : Cell[_, "Output", ___] :> Rasterize[RawBoxes[c]], \[Infinity]], ImagePadding -> 10, Background -> Transparent]

Out[2]=

Crie uma colagem de todos os resultados de gráficos dos exemplos de documentação de Plot.

In[3]:=

evaluate[l_List] := Module[{p}, p = l /. RawBoxes[Cell[BoxData[wlc_], "Input", ___]] :> ToExpression[wlc, StandardForm, Hold]; Block[Evaluate[ Select[Union[Cases[p, _Symbol, {-1}]], Quiet[Context[#] === "Global`"] &]], ReleaseHold /@ p]]

In[4]:=

ImageCollage[ Rasterize[#, ImageSize -> 100] & /@ Cases[Flatten[ evaluate /@ Flatten[WolframLanguageData["Plot", "DocumentationExampleInputs"][[All, -1]], 1]], _Graphics], ImagePadding -> 2] // Quiet

Out[4]=

Veja as imagens de pessoas associadas com o símbolo LaplacianGaussianFilter na Wolfram Language.

In[5]:=

ImageAssemble[ PersonData[ WolframLanguageData["LaplacianGaussianFilter", "EponymousPeople"], "Image"]]

Out[5]=

Extraia as pessoas que deram nome aos símbolos da Wolfram Language.

In[6]:=

people = DeleteCases[ Union[Flatten[ WolframLanguageData[All, "EponymousPeople"]]], _Missing];

Obtenha informações sobre seus locais de nascimento.

In[7]:=

placedata = DeleteCases[ PersonData[ people, {"Image", "BirthPlace", "Name"}], {_, _Missing, _}];

Veja esses locais e as pessoas associadas a eles em um mapa do mundo.

In[8]:=

GeoGraphics[ Tooltip[Point[#2], Column[DeleteCases[{##} /. e_Entity :> CommonName[e], _Missing]]] & @@@ placedata] // Quiet

Out[8]=

Extraia as datas de nascimento e de morte das pessoas que seram nome a símbolos da Wolfram Language.

In[9]:=

timedata = Block[{EntityFramework`$EntityValueBatchSize = 300}, DeleteCases[ PersonData[ people, {"BirthDate", "DeathDate", "Name", "Image"}], {_Missing, __}]];

Faça um gráfico da linha do tempo.

In[10]:=

formatdates[d1_, d2_] := Row[Riffle[Switch[#, Missing["Alive"], "present", _Missing, "????", _, DateString[#, {"MonthName", " ", "DayShort", ", ", "Year"}] ] & /@ {d1, d2}, "-"]]

In[11]:=

TimelinePlot[ Association @@ ((Tooltip[StringSplit[#3, " "][[-1]], Column[{#4, #3, formatdates[#1, #2]}]] -> #1) & @@@ Select[timedata, #[[1]] > DateObject[{1800}] &])]

Out[11]=