Wolfram 언어의 시각화: Wolfram Language 11의 신기능

Wolfram 언어의 시각화

Wolfram 언어의 구조와 Wolfram Knowledgebase와의 관계는 다양한 방법으로 시각화할 수 있습니다. 이 예에서는 둘의 관계 특징을 감싸는 워드 클라우드를 만들고, 계산으로 검토하고 문서로부터 아웃풋 예제를 모아 정리하고, Wolfram 언어 기호의 일부로 이름이 사용되고 있는 인물과 관련된 위치 및 시점을 시각화하기도 합니다.

WolframLanguageData 문서에 사용된 용어의 워드 클라우드를 작성합니다.

In[1]:=

WordCloud[
 DeleteStopwords[
  Flatten[TextWords[
    WolframLanguageData["WolframLanguageData", "TextStrings"]]]]]

Out[1]=

Plot의 기본 문서 예제 아웃풋의 콜라주를 생성합니다.

In[2]:=

ImageCollage[
 Cases[WolframLanguageData["Plot", "DocumentationBasicExamples"], 
  c : Cell[_, "Output", ___] :> Rasterize[RawBoxes[c]], \[Infinity]], 
 ImagePadding -> 10, Background -> Transparent]

Out[2]=

Plot에 대한 "전체" 문서의 예제 아웃풋 그래픽을 생성합니다.

전체 Wolfram 언어 입력 표시하기

In[3]:=

evaluate[l_List] := 
 Module[{p}, 
  p = l /. RawBoxes[Cell[BoxData[wlc_], "Input", ___]] :> 
     ToExpression[wlc, StandardForm, Hold];
  Block[Evaluate[
    Select[Union[Cases[p, _Symbol, {-1}]], 
     Quiet[Context[#] === "Global`"] &]], ReleaseHold /@ p]]

In[4]:=

ImageCollage[
  Rasterize[#, ImageSize -> 100] & /@ 
   Cases[Flatten[
     evaluate /@ 
      Flatten[WolframLanguageData["Plot", 
         "DocumentationExampleInputs"][[All, -1]], 1]], _Graphics], 
  ImagePadding -> 2] // Quiet

Out[4]=

Wolfram 언어의 LaplacianGaussianFilter 기호와 관계 인물의 이미지를 살펴봅니다.

In[5]:=

ImageAssemble[
 PersonData[
  WolframLanguageData["LaplacianGaussianFilter", "EponymousPeople"], 
  "Image"]]

Out[5]=

Wolfram 언어 기호의 유래가 된 인물을 추출합니다.

In[6]:=

people = DeleteCases[
   Union[Flatten[
     WolframLanguageData[All, "EponymousPeople"]]], _Missing];

그 인물의 태어난 곳의 정보를 얻을 수 있습니다.

In[7]:=

placedata = 
  DeleteCases[
   PersonData[
    people, {"Image", "BirthPlace", "Name"}], {_, _Missing, _}];

이 장소와 관련된 인물을 세계 지도에서 살펴봅니다.

전체 Wolfram 언어 입력 표시하기

In[8]:=

GeoGraphics[
  Tooltip[Point[#2], 
     Column[DeleteCases[{##} /. 
        e_Entity :> CommonName[e], _Missing]]] & @@@ 
   placedata] // Quiet

Out[8]=

Wolfram 언어의 기호 이름의 유래가 된 인물의 출생일과 사망일을 추출합니다.

In[9]:=

timedata = 
  Block[{EntityFramework`$EntityValueBatchSize = 300}, 
   DeleteCases[
    PersonData[
     people, {"BirthDate", "DeathDate", "Name", 
      "Image"}], {_Missing, __}]];

타임 라인 플롯을 작성합니다.

전체 Wolfram 언어 입력 표시하기

In[10]:=

formatdates[d1_, d2_] := Row[Riffle[Switch[#,
      Missing["Alive"], "present",
      _Missing, "????",
      _, DateString[#, {"MonthName", " ", "DayShort", ", ", "Year"}]
      ] & /@ {d1, d2}, "-"]]

In[11]:=

TimelinePlot[
 Association @@ ((Tooltip[StringSplit[#3, " "][[-1]], 
        Column[{#4, #3, formatdates[#1, #2]}]] -> #1) & @@@ 
    Select[timedata, #[[1]] > DateObject[{1800}] &])]

Out[11]=

Wolfram 언어™

Wolfram 언어의 시각화

관련 예제