Définissez des règles de grammaire : Nouveautés de Wolfram Language 11

Définissez des règles de grammaire

Créez votre propre interface de traitement du langage naturel, en combinant les puissants éléments et règles de grammaire intégrés du cadre Interpreter avec vos propres éléments et règles de grammaire personnalisés. Déployez ensuite l'interface dans Wolfram Cloud pour une utilisation ultérieure dans des fonctions telles que GrammarApply.

Utilisez le type d'interprète intégré "City" afin de construire un analyseur syntaxique pour une liste de noms de villes avec différents délimiteurs et déployez-le dans le cloud.

In[1]:=

citiesGrammar = CloudDeploy[
  GrammarRules[{
    cs : DelimitedSequence[GrammarToken["City"], "," | ";" | "and"] :>
      cs
    }]
  ]

Out[1]=

Appliquez l'analyseur syntaxique à une chaîne de caractères contenant plusieurs villes des États-Unis, en renvoyant une liste d'objets Entity respectifs.

In[2]:=

GrammarApply[citiesGrammar, "Saint Louis; New York, LA and Dallas"]

Out[2]=

Ils peuvent maintenant être traités par la fonctionnalité géographique de Wolfram.

In[3]:=

GrammarApply[citiesGrammar, "Saint Louis; New York, LA and Dallas"];
GeoListPlot[%, GeoLabels -> Automatic, 
 GeoBackground -> "CountryBorders", GeoRange -> "Country"]

Out[3]=

Ajoutez vos propres mots-clés grammaticaux "Route", "Origin" et "Destination" et définissez des règles pour chacun d'entre eux.

In[4]:=

routeGrammar = CloudDeploy[
  GrammarRules[{GrammarToken["Route"], GrammarToken["Origin"], 
    GrammarToken["Destination"]},
   {
    "Route" -> 
     AnyOrder[start : GrammarToken["Origin"], 
       end : GrammarToken["Destination"]] :> (start -> end),
    "Origin" -> 
     FixedOrder["from", loc : GrammarToken["City"]] :> loc,
    "Destination" -> 
     FixedOrder["to", loc : GrammarToken["City"]] :> loc
    }
   ]
  ]

Out[4]=

L'utilisation combinée d'AnyOrder et FixedOrder permet une analyse correcte de l'origine et de la destination dans les deux ordres.

In[5]:=

GrammarApply[routeGrammar, "from NYC to LA"]

Out[5]=

In[6]:=

GrammarApply[routeGrammar, "to LA from NYC"]

Out[6]=

Wolfram Language™

Définissez des règles de grammaire

Exemples connexes