Consultez Wolfram Knowledgebase en utilisant le langage naturel
Créez une fonction pour rechercher des chansons par artiste et album et générez une table avec des informations de compositeur.
In[1]:=
songLookup[act_, album_] :=
Module[{actEntity, albumEntity, songs, composers},
actEntity = Interpreter["MusicAct"][act];
albumEntity = Interpreter["MusicAlbum"][album];
songs =
EntityList[
EntityClass[
"MusicWork", {"AssociatedMusicActs" -> actEntity,
"AssociatedMusicAlbums" -> albumEntity}]];
composers = EntityValue[songs, "Composers"];
Column[{albumEntity["Image"],
Grid[Transpose[{songs, composers}],
Background -> {Automatic, {{LightOrange, White}}}]}]]Déployez une grammaire simple qui utilise des interprètes intégrés pour reconnaître les types d'entités "MusicAct" et "MusicAlbum".
In[2]:=
songGrammar = CloudDeploy[
GrammarRules[
{AnyOrder[
OptionalElement[
FixedOrder[
"songs" | "titles" | "tracks" | "tunes" | "recordings",
OptionalElement["by" | "from"]]],
act : GrammarToken["MusicAct"],
FixedOrder[OptionalElement["from" | "on"],
album : GrammarToken["MusicAlbum"]]
] :> songLookup[act, album]}]]Out[3]=
In[4]:=
GrammarApply[songGrammar, "tracks by Michael Jackson on Thriller"]Out[4]=
In[5]:=
GrammarApply[songGrammar, "Pink Floyd's Dark Side of the Moon"]Out[5]=
