Wolfram Language™

Comparez la structure de phrases

La structure de deux phrases peuvent être comparées en calculant en traitant leurs graphiques constitutifs respectifs.

Affichez l'arbre de constituants d'une phrase comme un graphe.

In[1]:=

graph = TextStructure["Time flies like an arrow.", "ConstituentGraph"]

Out[1]=

Calculez la matrice des distances entre tous les sommets de ce graphe.

In[2]:=

distancemat1 = GraphDistanceMatrix[First[graph]]; MatrixForm[distancemat1]

Out[2]//MatrixForm=

Procédez de même pour une autre phrase.

In[3]:=

graph2 = TextStructure["I fly in the sky.", "ConstituentGraph"]; distancemat2 = GraphDistanceMatrix[First[graph2]];

Comparez la structure de deux phrases en comparant leurs matrices de distance.

In[4]:=

distancemat1 == distancemat2

Out[4]=

Les deux phrases ont la même structure.

Trouvez des phrases avec des structures identiques dans deux articles différents de Wikipédia. Tout d'abord, extrayez des phrases avec un nombre de mots donnés et générez le graphe constituant pour chacune d'elles.

In[5]:=

processWikiPage[article_] := Select[TextCases[WikipediaData[article], "Sentences"], WordCount[#] < 5 &]; genStructure[article_] := Flatten[TextStructure[#, "ConstituentGraph"] & /@ processWikiPage[article]];

In[6]:=

phrasestruct1 = genStructure["Philosophy"]; phrasestruct2 = genStructure["History"];

Calculez toutes les matrices de distance.

In[7]:=

adj1 = GraphDistanceMatrix /@ phrasestruct1; adj2 = GraphDistanceMatrix /@ phrasestruct2;

Comparez les deux phrases des différents articles deux par deux.

In[8]:=

comparison = Outer[Equal, adj1, adj2, 1];

Voici les paires phrases ayant la même structure.

In[9]:=

pickedSentences = Flatten[Pick[Outer[List, phrasestruct1, phrasestruct2], comparison, True], 1];

Voici la première paire.

In[10]:=

First[pickedSentences]

Out[10]=