계절적 패턴 시각화
미국 중서부와 남서부의 계절별 강수량을 비교합니다.
WeatherData 총 강수량을 cm 단위로 제공합니다.
In[1]:=
![Click for copyable input](assets.ko/visualize-seasonal-patterns/In_63.png)
start = {1999, 1, 1};
end = {2015, 12, 31};
In[2]:=
![Click for copyable input](assets.ko/visualize-seasonal-patterns/In_64.png)
getData[place_] :=
WeatherData[place, "TotalPrecipitation", {start, end, "Month"}]
일리노이 주 샴페인과 애리조나 주 피닉스의 강수량 TimeSeries를 작성합니다. MissingDataMethod를 지정하여 결손 데이터 보완 보간에 사용합니다.
In[3]:=
![Click for copyable input](assets.ko/visualize-seasonal-patterns/In_65.png)
makeTS[place_] :=
TimeSeries[getData[place], MissingDataMethod -> "Interpolation"]
In[4]:=
![Click for copyable input](assets.ko/visualize-seasonal-patterns/In_66.png)
tsIL = makeTS[
Entity["City", {"Champaign", "Illinois", "UnitedStates"}]]
Out[4]=
![](assets.ko/visualize-seasonal-patterns/O_35.png)
In[5]:=
![Click for copyable input](assets.ko/visualize-seasonal-patterns/In_67.png)
tsAZ = makeTS[Entity["City", {"Phoenix", "Arizona", "UnitedStates"}]]
Out[5]=
![](assets.ko/visualize-seasonal-patterns/O_36.png)
강수량을 무게로 하는 WeightedData를 작성하고 데이터를 총 합계 연수로 평균 한 DateHistogram을 플롯합니다.
In[6]:=
![Click for copyable input](assets.ko/visualize-seasonal-patterns/In_68.png)
dataIL = WeightedData[tsIL["Dates"], tsIL["Values"]];
dataAZ = WeightedData[tsAZ["Dates"], tsAZ["Values"]];
In[7]:=
![Click for copyable input](assets.ko/visualize-seasonal-patterns/In_69.png)
totalyears = (end[[1]] - start[[1]] + 1);
In[8]:=
![Click for copyable input](assets.ko/visualize-seasonal-patterns/In_70.png)
avg := Function[{x, y}, y/totalyears]
In[9]:=
![Click for copyable input](assets.ko/visualize-seasonal-patterns/In_71.png)
makeHistogram[data_, lab_] :=
DateHistogram[data, "Month", avg, DateReduction -> "Year",
PlotRange -> {All, {-1, 9}}, AxesLabel -> "cm", PlotLabel -> lab]
In[10]:=
![Click for copyable input](assets.ko/visualize-seasonal-patterns/In_72.png)
{makeHistogram[dataIL, "IL"], makeHistogram[dataAZ, "AZ"]}
Out[10]=
![](assets.ko/visualize-seasonal-patterns/O_37.png)