날짜가 지정된 시계열의 필터 적용: Wolfram Language 11의 신기능

날짜가 지정된 시계열의 필터 적용

WeatherData를 사용하여 지정된 날짜의 기온을 얻을 수 있습니다. MissingDataMethod를 지정하여 결손 데이터를 보간하는 새로운 시계열을 생성합니다.

In[1]:=

data = TimeSeries[
  WeatherData["Chicago", 
   "Temperature", {{2015, 1, 1}, {2015, 12, 31}}], 
  MissingDataMethod -> "Interpolation"]

Out[1]=

In[2]:=

DateListPlot[data, FrameLabel -> Automatic]

Out[2]=

MinFilter를 사용하여 주어진 해의 처음과 마지막 결빙 시기를 분석합니다.

In[3]:=

minF = MinFilter[data, Quantity[1, "Month"]];

전체 Wolfram 언어 입력 표시하기

In[4]:=

freezeline = {{minF["FirstDate"], 0}, {minF["LastDate"], 0}};

In[5]:=

DateListPlot[{data, minF, freezeline}, FrameLabel -> Automatic]

Out[5]=

봄의 마지막 결빙일의 다음날을 알아봅니다.

In[6]:=

spring = TimeSeriesWindow[minF, {"15 April 2015", "15 May 2015"}];

In[7]:=

DateObject[
 First@FirstCase[
   spring["Path"], _?(#[[2]] > Quantity[0, "DegreesCelsius"] &)]]

Out[7]=

가을의 첫 결빙일을 알아봅니다.

In[8]:=

fall = TimeSeriesWindow[minF, {"1 Oct 2015", "31 Oct 2015"}];

In[9]:=

DateObject[
 First@FirstCase[
   fall["Path"], _?(#[[2]] <= Quantity[0, "DegreesCelsius"] &)]]

Out[9]=