Wolfram 언어

시계열 데이터와 조작

신호 도함수의 근사

MovingMap을 사용하여 불규칙하게 샘플링 된 연속 시계열에서의 신호의 도함수를 근사합니다.

In[1]:=
Click for copyable input
ts = TimeSeries[ Table[{t, EllipticTheta[1, t, 0.3]}, {t, Join[{0.}, RandomReal[{0, 2 Pi}, 254], {2. Pi}]}]]
Out[1]=
In[2]:=
Click for copyable input
RegularlySampledQ[ts]
Out[2]=
In[3]:=
Click for copyable input
ListPlot[ts, PlotTheme -> "Detailed"]
Out[3]=

각 이동 창 경계에 있어서의 값과 시간을 사용하여 차분상을 계산합니다.

In[4]:=
Click for copyable input
quotient[values_, times_] := First[Differences[values]/Differences[times]]
In[5]:=
Click for copyable input
mm = MovingMap[quotient[#BoundaryValues, #BoundaryTimes] &, ts, {.01, Right}]
Out[5]=

이론상의 도함수와 비교합니다.

In[6]:=
Click for copyable input
prime = D[EllipticTheta[1, t, 0.3], t]
Out[6]=
In[7]:=
Click for copyable input
Show[Plot[prime, {t, 0, 2 \[Pi]}, PlotStyle -> Thick, PlotTheme -> "Detailed", PlotLegends -> None], ListPlot[mm, PlotStyle -> Red]]
Out[7]=

몫 함수 대신 Line을 사용한 MovingMap에서 오리지널 시계열을 근사하는 시컨트 플롯을 생성합니다.

In[8]:=
Click for copyable input
line[yvals_, xvals_] := Line[Transpose[{xvals, yvals}]];
In[9]:=
Click for copyable input
lines = MovingMap[ line[#BoundaryValues, #BoundaryTimes] &, ts, {1.3, Right, {0, 2. \[Pi], .1}}];
In[10]:=
Click for copyable input
Graphics[{Black, lines["Values"]}]
Out[10]=

관련 예제

de en es fr ja pt-br ru zh