Wolfram言語

単位と日付

均時差

地球軌道の離心率と軌道平面に対する地軸の傾きのために,太陽の視運動は一年を通して変化する.このため,日時計(視太陽時)で計測した時間と,例えば恒星の視回転で決定される(恒星時),より正確な時計との間には違いが生じる.この違いは均時差として知られるものである.

SiderealTimeは,恒星時の値を,MixedUnitを使って混合単位の数量として返す.

In[1]:=
Click for copyable input
SiderealTime[]
Out[1]=
In[2]:=
Click for copyable input
SiderealTime[]; QuantityUnit[%]
Out[2]=

構成時は,実際には角度であり,したがって,他の角度単位に変換することができる.

In[3]:=
Click for copyable input
UnitConvert[SiderealTime[], "AngularDegrees"]
Out[3]=

均時差は,SunPositionで与えられる太陽の動きで決定される.グリニッジ標準時の正午における1週間の値を計算する.

In[4]:=
Click for copyable input
dates = DateRange[ DateObject[{2015, 1, 1}, TimeObject[{12, 0}, TimeZone -> 0], TimeZone -> 0.`], DateObject[{2015, 12, 31}, TimeObject[{12, 0}, TimeZone -> 0], TimeZone -> 0.`], 7];
In[5]:=
Click for copyable input
sunpos = SunPosition[GeoPosition[{0, 0}], dates, CelestialSystem -> "Equatorial"]
Out[5]=

同じ週日について,SiderealTimeを使ってグリニッジ子午線における赤経を計算する.

In[6]:=
Click for copyable input
stime = SiderealTime[GeoPosition[{0, 0}], dates]
Out[6]=

最後に,均時差の対応する値を正午における太陽の赤経と恒星時の違いとして1年を通じて求める.結果を分単位で表す.

In[7]:=
Click for copyable input
equationoftime = UnitConvert[(TimeSeriesMap[First, sunpos] - stime), "MinutesOfRightAscension"]
Out[7]=

均時差の絶対値は15分より大きくなることがある.

In[8]:=
Click for copyable input
MinMax[equationoftime]
Out[8]=
完全なWolfram言語入力を表示する
In[9]:=
Click for copyable input
DateListPlot[equationoftime, GridLines -> Automatic, Axes -> True, PlotTheme -> "Web"]
Out[9]=

関連する例

de en es fr ko pt-br ru zh