Wolfram Language

Einheiten & Datumsangaben

Die Zeitgleichung

Aufgrund der Exzentrizität der Erdumlaufbahn und der Neigung der Erdachse in Bezug auf die Ebene der Umlaufbahn variiert die scheinbare Bewegung der Sonne im Laufe des Jahres. Dies bedeutet einen Unterschied zwischen der Zeit, die von einer Sonnenuhr gemessen wird (scheinbare Sonnenzeit) und jener, die von einer präziseren Uhr wie zum Beispiel einer, die auf der scheinbaren Drehung der Erde vor einem Fixsternhintergrund basiert (Sternzeit), gemessen wird. Diese Differenz ist bekannt als die Zeitgleichung.

SiderealTime gibt Werte der Sternzeit mithilfe von MixedUnit als gemischte Einheiten zurück.

In[1]:=
Click for copyable input
SiderealTime[]
Out[1]=
In[2]:=
Click for copyable input
SiderealTime[]; QuantityUnit[%]
Out[2]=

Die Sternzeit ist eigentlich ein Winkel und kann daher in andere Winkeleinheiten zerlegt werden.

In[3]:=
Click for copyable input
UnitConvert[SiderealTime[], "AngularDegrees"]
Out[3]=

Die Zeitgleichung wird durch die Bewegung der Sonne bestimmt, gegeben durch SunPosition. Berechnen Sie die wöchentlichen Werte zu GMT-Mittagszeit.

In[4]:=
Click for copyable input
dates = DateRange[ DateObject[{2015, 1, 1}, TimeObject[{12, 0}, TimeZone -> 0], TimeZone -> 0.`], DateObject[{2015, 12, 31}, TimeObject[{12, 0}, TimeZone -> 0], TimeZone -> 0.`], 7];
In[5]:=
Click for copyable input
sunpos = SunPosition[GeoPosition[{0, 0}], dates, CelestialSystem -> "Equatorial"]
Out[5]=

Verwenden Sie SiderealTime, um die Rektaszension am Greenwich-Meridian immer am selben Wochentag zu berechnen.

In[6]:=
Click for copyable input
stime = SiderealTime[GeoPosition[{0, 0}], dates]
Out[6]=

Ermitteln Sie schließlich die entsprechenden Werte der Zeitgleichung als die Differenz zwischen der Rektaszension der Sonne und der Sternzeit jeweils zu Mittag im Laufe eines Jahres. Drücken Sie das Ergebnis in Minuten aus.

In[7]:=
Click for copyable input
equationoftime = UnitConvert[(TimeSeriesMap[First, sunpos] - stime), "MinutesOfRightAscension"]
Out[7]=

Die absoluten Werte der Zeitgleichung können größer als 15 Minuten sein.

In[8]:=
Click for copyable input
MinMax[equationoftime]
Out[8]=
Den kompletten Wolfram Language-Input zeigen
In[9]:=
Click for copyable input
DateListPlot[equationoftime, GridLines -> Automatic, Axes -> True, PlotTheme -> "Web"]
Out[9]=

Verwandte Beispiele

en es fr ja ko pt-br ru zh