Stellen Sie eine komplexe analytische Funktion auf
Stellen Sie eine komplexe analytische Funktion auf, angefangen mit den Werten ihrer rellen und imaginären Teile auf der -Achse.
Die reellen und imaginären Teile u und v genügen den Cauchy–Riemann-Gleichungen.
In[1]:=
creqns = {D[u[x, y], x] == D[v[x, y], y],
D[v[x, y], x] == -D[u[x, y], y]};
Schreiben Sie die Werte von u und v auf der -Achse vor.
In[2]:=
xvals = {u[x, 0] == x^3, v[x, 0] == 0};
Lösen Sie die Cauchy–Riemann-Gleichungen.
In[3]:=
sol = DSolve[{creqns, xvals}, {u, v}, {x, y}]
Out[3]=
Vergewissern Sie sich, dass die Lösungen harmonische Funktionen sind.
In[4]:=
Laplacian[{u[x, y], v[x, y]} /. sol[[1]], {x, y}]
Out[4]=
Visualisieren Sie die von der Lösung erzeugten Stromlinien und Äquipotentiallinien.
In[5]:=
ContourPlot[{u[x, y], v[x, y]} /. sol[[1]], {x, -5, 5}, {y, -5, 5},
ContourStyle -> {Red, Blue}]
Out[5]=
Stellen Sie auf Grundlage der Lösung eine komplexe analytische Funktion auf.
In[6]:=
f[x_, y_] = u[x, y] + I v[x, y] /. sol[[1]]
Out[6]=
Dies ist eine Darstellung der Funktion .
In[7]:=
(f[x, y] // Factor) /. {x + I y -> z}
Out[7]=