Решение начальной задачи для волнового уравнения
Задать волновое уравнение с приведённой частотой распространения.
In[1]:=
weqn = D[u[x, t], {t, 2}] == D[u[x, t], {x, 2}];
Задать начальные условия для уравнения.
In[2]:=
ic = {u[x, 0] == E^(-x^2), Derivative[0, 1][u][x, 0] == 1};
Решить начальную задачу.
In[3]:=
DSolveValue[{weqn, ic}, u[x, t], {x, t}]
Out[3]=
Волна распространяется по характерным направлениям.
In[4]:=
DSolveValue[{weqn, ic}, u[x, t], {x, t}];
Plot3D[%, {x, -7, 7}, {t, 0, 4}, Mesh -> None]
Out[4]=
Решить начальную задачу с фрагментированными данными.
In[5]:=
ic = {u[x, 0] == UnitBox[x] + UnitTriangle[x/3],
Derivative[0, 1][u][x, 0] == 0};
In[6]:=
DSolveValue[ {weqn, ic}, u[x, t], {x, t}]
Out[6]=
Разрывы в начальных данных распространяются по характерным направлениям.
In[7]:=
DSolveValue[ {weqn, ic}, u[x, t], {x, t}];
Plot3D[%, {x, -7, 7}, {t, 0, 4}, PlotRange -> All, Mesh -> None,
ExclusionsStyle -> Red]
Out[7]=
Решить начальную задачу с суммой экспоненциальных функций в качестве начальных данных.
In[8]:=
ic = {u[x, 0] == E^(-(x - 6)^2) + E^(-(x + 6)^2),
Derivative[0, 1][u][x, 0] == 1/2};
In[9]:=
sol = DSolveValue[ {weqn, ic}, u[x, t], {x, t}]
Out[9]=
Визуализировать решение.
In[10]:=
Plot3D[sol, {x, -30, 30}, {t, 0, 20}, PlotRange -> All, Mesh -> None,
PlotPoints -> 30]
Out[10]=