Wolfram Language

Géométrie de calcul

Moment d'inertie

Explorez les nouvelles capacités couvrant les paramètres physiques d'un corps rigide incluant l'inertie de rotation.

In[1]:=
Click for copyable input
wrench = ExampleData[{"Geometry3D", "Wrench"}, "Region"]
Out[1]=

Choisissez un point autour duquel la clé doit tourner.

In[2]:=
Click for copyable input
point = {-8, -0.168, 0};
In[3]:=
Click for copyable input
Show[wrench, Graphics3D[{PointSize[Large], Point[point]}], ViewPoint -> {0, -\[Infinity], 0}]
Out[3]=

La matrice d'inertie est centrée sur ce point.

In[4]:=
Click for copyable input
\[ScriptCapitalI] = MomentOfInertia[wrench, point]
Out[4]=

Trouvez les principaux axes, les axes autour desquels un corps a tendance à tourner.

In[5]:=
Click for copyable input
principalaxes = Eigenvectors[\[ScriptCapitalI]]
Out[5]=

Trouvez l'ellipsoïde d'inertie dont les rayons indiquent la résistance relative à l'accélération autour d'un axe principal.

In[6]:=
Click for copyable input
inertiaellipsoid = Ellipsoid[point, 1000 Inverse[\[ScriptCapitalI]]]
Out[6]=

Affichez la clé avec ses principaux axes et l'ellipsoïde d'inertie. Le bras de la clé étire l'ellipsoïde le long de son axe.

Afficher l'entrée complète de Wolfram Language
In[7]:=
Click for copyable input
axes = Graphics3D[{Opacity[1], Arrowheads[{-0.04, 0.04}], {Specularity[Gray, 10], Gray, inertiaellipsoid}, MapThread[{RGBColor[#2], Arrow[Tube[{point - 4 #, point + 4 #}, .06]]} &, {principalaxes, IdentityMatrix[3]}]}];
In[8]:=
Click for copyable input
Show[wrench, axes, BaseStyle -> Opacity[0.3]]
Out[8]=

Exemples connexes

de en es ja ko pt-br ru zh