Доступ к содержанию Википедии через использование понятий языка : Новое в системе Wolfram Language 11

Доступ к содержанию Википедии через использование понятий языка

Pастущее количество понятий базы знаний Wolfram сопоставимо с внешними информационными ресурсами, включая Википедию.

Использовать WikipediaData для получения страниц этих понятий и первых предложений с каждой страницы.

In[1]:=

entities = {Entity["Person", "JohnLennon::cpwy3"], 
   Entity["Species", "Species:AcinonyxJubatus"], 
   Entity["City", {"NewYork", "NewYork", "UnitedStates"}], 
   Entity["MusicAct", "PinkFloyd::7523m"], 
   Entity["AdministrativeDivision", {"Florida", "UnitedStates"}]};

In[2]:=

summaries = 
  Table[{ent, First[TextSentences[WikipediaData[ent]]]}, {ent, 
    entities}];

Создать отформатированную коллекцию кратких текстовых изложений о понятиях.

код на языке Wolfram Language целиком

In[3]:=

Panel[TextGrid[summaries, 
  Background -> {Automatic, {{LightOrange, White}}}, 
  Alignment -> Left], ImageSize -> 500]

Out[3]=

Запросить статьи Википедии для каждого музыканта группы Rolling Stones.

In[4]:=

stones = Entity["MusicAct", "TheRollingStones::99n5n"]["Members"]

Out[4]=

In[5]:=

stonesWiki = WikipediaData[stones];

Создать коллаж из словарных облаков, взвешенных по количеству слов в статье.

код на языке Wolfram Language целиком

In[6]:=

weightedStonesClouds = 
  WordCount[#] -> WordCloud[DeleteStopwords[#]] & /@ 
   DeleteMissing[stonesWiki];
ImageCollage[weightedStonesClouds, Method -> "Columns"]

Out[6]=