Визуализация и анализ анатомических строений : Новое в системе Wolfram Language 11

Визуализация и анализ анатомических строений

Графически изобразить строение кости и кожи стопы человека и приблизительно рассчитать площадь её поверхности (в квадратных миллиметрах).

In[1]:=

Row[EntityValue[{Entity["AnatomicalStructure", "RightFoot"], 
   Entity["AnatomicalStructure", "SkinOfRightFoot"]}, "MeshRegion"]]

Out[1]=

In[2]:=

Area[EntityValue[Entity["AnatomicalStructure", "SkinOfRightFoot"], 
  "MeshRegion"]]

Out[2]=

Графически изобразить соединение периферийных ветвей плечевой артерии.

In[3]:=

NestGraph[Cases[EntityValue[#, "Branches"], _Entity] &, 
 Entity["AnatomicalStructure", "BrachialArtery"], 3, 
 VertexLabels -> Placed["Name", Tooltip], EdgeStyle -> Pink, 
 VertexStyle -> Pink, GraphStyle -> "BasicBlack"]

Out[3]=

Найти части левого предплечья.

In[4]:=

g = NestGraph[Cases[EntityValue[#, "ConstitutionalParts"], _Entity] &,
   Entity["AnatomicalStructure", "LeftForearm"], 2]

Out[4]=

Вычислить общую длину глотки, пищевода, желудка, малого кишечника и большого кишечника.

In[5]:=

UnitConvert[
 EntityValue[
  EntityGroup[{Entity["AnatomicalStructure", "Pharynx"], 
    Entity["AnatomicalStructure", "Esophagus"], 
    Entity["AnatomicalStructure", "Stomach"], 
    Entity["AnatomicalStructure", "SmallIntestine"], 
    Entity["AnatomicalStructure", "LargeIntestine"]}], 
  "Length"], "Metric"]

Out[5]=

Сравнить длину и ширину стопы у мужчин и женщин.

In[6]:=

# -> (UnitConvert[#, "Centimeters"] & /@ 
     EntityValue[
      EntityInstance[Entity["AnatomicalStructure", "Foot"], 
       "Gender" -> #], {"Length", "Width"}, 
      "PropertyAssociation"]) & /@ {"Female", "Male"}

Out[6]=