Язык Wolfram Language

Расширение базы знаний

Визуализируйте силу сопротивления материалов

Частицы радиации теряют свою кинетическую энергию, когда они проходят сквозь материю, и в итоге останавливаются или поглощаются. Данный пример рассматривает силу сопротивления субстанций, облучённых альфа частицами.

Графически изобразите линейную силу сопротивления биологической ткани, облучённой частицами альфа различных видов ударной энергии. Вертикальная ось показывает, сколько энергии в среднем теряют частицы за каждый сантиметр пройденного пути.

In[1]:=
Click for copyable input
ListLogLinearPlot[ Table[{Quantity[10^x, "Electronvolts"], StoppingPowerData[ "A150TissueEquivalentPlastic", {"Particle" -> Entity["Particle", "AlphaParticle"], "Energy" -> Quantity[10^x, "Electronvolts"]}, "LinearStoppingPower"]}, {x, 3, 8, 0.1}], AxesLabel -> Automatic]
Out[1]=

Изучить, как линейная сила сопротивления меняется для частицы альфа, выпущенной атомом урания во время прохождения частицы через биологическую ткань. Это является начальной кинетической энергией частицы.

In[2]:=
Click for copyable input
initialKE = IsotopeData[Entity["Isotope", "Uranium235"], "BindingEnergy"]
Out[2]=
код на языке Wolfram Language целиком
In[3]:=
Click for copyable input
dEByDxVal[k_Real?Positive] := QuantityMagnitude[ StoppingPowerData[ "A150TissueEquivalentPlastic", {"Particle" -> Entity["Particle", "AlphaParticle"], "Energy" -> Quantity[k, "Megaelectronvolts"]}, "LinearStoppingPower"]]/10000; dEByDxVal[k_Real] := 0
In[4]:=
Click for copyable input
sol = NDSolveValue[{KiM'[x] == -dEByDxVal[KiM[x]], KiM[0] == QuantityMagnitude[initialKE], WhenEvent[KiM[x] <= 0, "StopIntegration"]}, KiM, {x, 0, 60}, PrecisionGoal -> 3];

Отобразить понижение кинетической энергии, когда частица проходит через единицу материала и до момента её остановки приблизительно при .

код на языке Wolfram Language целиком
In[5]:=
Click for copyable input
Plot[sol[x], {x, 0, 60}, Frame -> True, GridLines -> Automatic, FrameLabel -> {"distance traveled (\[Micro]m)", Row[{"KE", " (", Quantity[None, "Megaelectronvolts"], ")"}]}]
Out[5]=

Представить скорости потери энергии на одну единицу длины.

код на языке Wolfram Language целиком
In[6]:=
Click for copyable input
Plot[dEByDxVal[sol[x]], {x, 0, 60}, Frame -> True, GridLines -> Automatic, FrameLabel -> {"distance traveled (\[Micro]m)", Row[{"\[DifferentialD]", Style["E", Italic], "/", "\[DifferentialD]", Style["x", Italic], " (", Quantity[None, "Megaelectronvolts"/"Micrometers"], ")"}]}]
Out[6]=

Родственные примеры

de en es fr ja ko pt-br zh