Генерирование пешего тура по достопримечательным зданиям: Новое в системе Wolfram Language 11

Генерирование пешего тура по достопримечательным зданиям

Использoвать GeoNearest для поиска примечательных зданий в радиусe 1 км вокруг здания городской администрации Бостона.

In[1]:=

position = Entity["Building", "BostonCityHall::96t3t"];
radius = Quantity[1, "Kilometers"];

In[2]:=

nearMe = GeoNearest["Building", position, {All, radius}]

Out[2]=

Графически изобразить эти здания на местной карте, используя встроенные иконки сущностей.

код на языке Wolfram Language целиком

In[3]:=

iconItemPairs = 
  With[{icon = EntityValue[Entity["Icon", "Museum"], "Image"][[1]]},
   MapThread[{#1, 
      Graphics[{EdgeForm[Black], FaceForm[#2], icon}, 
       "ImageSize" -> 25]} &, {nearMe, RandomColor[Length@nearMe]}]
   ];
legend = Column[
   Row[Reverse@#] & /@ (MapAt[CommonName, #, 1] & /@ iconItemPairs)];
Row[{
  GeoGraphics[{EdgeForm[Darker[Orange]], Orange, 
    GeoDisk[position, radius], GeoMarker[position, "Color" -> Red], 
    GeoMarker @@@ iconItemPairs}, ImageSize -> 400],
  legend
  }]

Out[3]=

Использовать TravelDirections, чтобы рассчитать пеший тур по всем этим достопримечательностям.

In[4]:=

tourPlaces = Prepend[nearMe, position];

In[5]:=

{distance, tourPath} = 
 FindShortestTour[GeoPosition /@ tourPlaces, 1, Length@tourPlaces]

Out[5]=

In[6]:=

travelDirectionsForPath = 
 TravelDirections[tourPlaces[[tourPath]], TravelMethod -> "Walking"]

Out[6]=

код на языке Wolfram Language целиком

In[7]:=

Row[{
  GeoGraphics[{
    Thickness[0.01], Darker@Red, GeoPath@travelDirectionsForPath,
    EdgeForm[Darker[Orange]], Orange, GeoDisk[position, radius],
    GeoMarker[position, "Color" -> Red], GeoMarker @@@ iconItemPairs
    }, ImageSize -> 400],
  legend
  }]

Out[7]=