Wolfram Language™

Kuratierte Datensätze mit eingebauten Daten ergänzen

Die umfangreiche Sammlung eingebauter sozioökonomischer Daten in der Wolfram Knowledgebase kann verwendet werden, um externe Datenquellen zu ergänzen.

Beginnen Sie mit einem Datensatz von Head Start-Standorten, importiert vom US Department of Housing and Urban Development (Ministerium für Wohnungsbau und Stadtentwicklung der Vereinigten Staaten).

In[1]:=

hs = ResourceData["Head Start Locations"][ All, {"CenterName", "CenterAddress", "CenterStateEntity", "CenterCityEntity", "CenterZipCodeEntity", "Coordinates"}];

In[2]:=

Take[hs, 5]

Out[2]=

Verwenden Sie einen Auswahloperator, um eine Teilmenge von Standorten zu extrahieren.

In[3]:=

hsChicago = hs[Select[#CenterCityEntity === Entity["City", {"Chicago", "Illinois", "UnitedStates"}] &]];

Veranschaulichen Sie diese auf einer Karte von Chicago.

In[4]:=

GeoListPlot[hsChicago[All, #Coordinates &]]

Out[4]=

Fassen Sie Head Start-Standorte zusammen und plotten Sie deren Verteilung nach ZIP-Code (US-Postleitzahl).

In[5]:=

chicagoCounts = Length /@ GroupBy[hsChicago, #CenterZipCodeEntity &];

In[6]:=

GeoRegionValuePlot[chicagoCounts]

Out[6]=

Rufen Sie eingebaute Daten über Chicagos Bevölkerung im schulpflichtigen Alter für jeden ZIP-Code ab und plotten Sie diese Werte in Gegenüberstellung zur jeweiligen Anzahl von Head Start-Standorten, die von den externen HUD-Daten abgeleitet wurde.

In[7]:=

zipcodes = Normal@Keys[chicagoCounts]

Out[7]=

In[8]:=

chicagoMedian = EntityValue[zipcodes, EntityProperty["ZIPCode", "Population", {"Age" -> "SchoolAge"}], "EntityAssociation"];

In[9]:=

locsVSkids = Merge[{Normal@chicagoCounts, chicagoMedian}, Identity]; ListPlot[locsVSkids, FrameLabel -> {"Head Start locations", "School age population"}, ImageSize -> 550, PlotTheme -> "Detailed"]

Out[9]=