Das Bremsvermögen eines Materials visualisieren: Neu in Wolfram Language 11

Das Bremsvermögen eines Materials visualisieren

Strahlungsteilchen verlieren kinetische Energie, wenn sie sich durch die Materie bewegen, bis sie schließlich stehen bleiben oder absorbiert werden. Dieses Beispiel untersucht das Bremsvermögen von Stoffen unter Alpha-Strahlung.

Plotten Sie das lineare Bremsvermögen eines biologischen Gewebes bei Alpha-Strahlung mit Teilchen unterschiedlich großer Energie. Die vertikale Achse veranschaulicht, wie viel Energie die Teilchen im Durchschnitt pro zurückgelegten Zentimeter verlieren.

In[1]:=

ListLogLinearPlot[
 Table[{Quantity[10^x, "Electronvolts"], 
   StoppingPowerData[
    "A150TissueEquivalentPlastic", {"Particle" -> 
      Entity["Particle", "AlphaParticle"], 
     "Energy" -> Quantity[10^x, "Electronvolts"]}, 
    "LinearStoppingPower"]}, {x, 3, 8, 0.1}], AxesLabel -> Automatic]

Out[1]=

Untersuchen Sie nun, wie sich das lineare Bremsvermögen eines Alpha-Teilchens, das von einem Uranium-Atom emittiert wird und sich durch biologisches Gewebe bewegt, verändert. Dies ist die kinetische Anfangsenergie des Teilchens.

In[2]:=

initialKE = 
 IsotopeData[Entity["Isotope", "Uranium235"], "BindingEnergy"]

Out[2]=

Den kompletten Wolfram Language-Input zeigen

In[3]:=

dEByDxVal[k_Real?Positive] := 
  QuantityMagnitude[
    StoppingPowerData[
     "A150TissueEquivalentPlastic", {"Particle" -> 
       Entity["Particle", "AlphaParticle"], 
      "Energy" -> Quantity[k, "Megaelectronvolts"]}, 
     "LinearStoppingPower"]]/10000;
dEByDxVal[k_Real] := 0

In[4]:=

sol = NDSolveValue[{KiM'[x] == -dEByDxVal[KiM[x]], 
    KiM[0] == QuantityMagnitude[initialKE],
      WhenEvent[KiM[x] <= 0, "StopIntegration"]}, KiM, {x, 0, 60},
    PrecisionGoal -> 3];

Veranschaulichen Sie den Rückgang der kinetischen Energie bei fortschreitender Bewegung des Teilchens im Material, bis es bei circa hält.

Den kompletten Wolfram Language-Input zeigen

In[5]:=

Plot[sol[x], {x, 0, 60}, Frame -> True, GridLines -> Automatic, 
 FrameLabel -> {"distance traveled (\[Micro]m)", 
   Row[{"KE", " (", Quantity[None, "Megaelectronvolts"], ")"}]}]

Out[5]=

Hier eine Veranschaulichung der Energieverlustrate pro Längeneinheit.

Den kompletten Wolfram Language-Input zeigen

In[6]:=

Plot[dEByDxVal[sol[x]], {x, 0, 60}, Frame -> True, 
 GridLines -> Automatic, 
 FrameLabel -> {"distance traveled (\[Micro]m)", 
   Row[{"\[DifferentialD]", Style["E", Italic], "/", 
     "\[DifferentialD]", Style["x", Italic], " (", 
     Quantity[None, "Megaelectronvolts"/"Micrometers"], ")"}]}]

Out[6]=

Wolfram Language™

Das Bremsvermögen eines Materials visualisieren

Verwandte Beispiele