Anatomische Strukturen visualisieren und analysieren: Neu in Wolfram Language 11

Anatomische Strukturen visualisieren und analysieren

Plotten Sie die Knochenstruktur und Haut des menschlichen Fußes und schätzen Sie den Flächeninhalt von dessen Oberfläche (in Quadratmillimetern).

In[1]:=

Row[EntityValue[{Entity["AnatomicalStructure", "RightFoot"], 
   Entity["AnatomicalStructure", "SkinOfRightFoot"]}, "MeshRegion"]]

Out[1]=

In[2]:=

Area[EntityValue[Entity["AnatomicalStructure", "SkinOfRightFoot"], 
  "MeshRegion"]]

Out[2]=

Plotten Sie die Konnektivität der Verästelungen der Oberarmarterie.

In[3]:=

NestGraph[Cases[EntityValue[#, "Branches"], _Entity] &, 
 Entity["AnatomicalStructure", "BrachialArtery"], 3, 
 VertexLabels -> Placed["Name", Tooltip], EdgeStyle -> Pink, 
 VertexStyle -> Pink, GraphStyle -> "BasicBlack"]

Out[3]=

Ermitteln Sie die Bestandteile des linken Unterarms.

In[4]:=

g = NestGraph[Cases[EntityValue[#, "ConstitutionalParts"], _Entity] &,
   Entity["AnatomicalStructure", "LeftForearm"], 2]

Out[4]=

Berechnen Sie die kombinierte Länge der Rachenhöhle, der Speiseröhre, des Magens, des Dünndarms und des Dickdarms.

In[5]:=

UnitConvert[
 EntityValue[
  EntityGroup[{Entity["AnatomicalStructure", "Pharynx"], 
    Entity["AnatomicalStructure", "Esophagus"], 
    Entity["AnatomicalStructure", "Stomach"], 
    Entity["AnatomicalStructure", "SmallIntestine"], 
    Entity["AnatomicalStructure", "LargeIntestine"]}], 
  "Length"], "Metric"]

Out[5]=

Vergleichen Sie die Länge und Breite eines weiblichen und eines männlichen Fußes.

In[6]:=

# -> (UnitConvert[#, "Centimeters"] & /@ 
     EntityValue[
      EntityInstance[Entity["AnatomicalStructure", "Foot"], 
       "Gender" -> #], {"Length", "Width"}, 
      "PropertyAssociation"]) & /@ {"Female", "Male"}

Out[6]=

Wolfram Language™

Anatomische Strukturen visualisieren und analysieren

Verwandte Beispiele