Visualisez la puissance de freinage des matériaux: Nouveautés de Wolfram Language 11

Visualisez la puissance de freinage des matériaux

Les particules de radiation perdent de l'énergie cinétique lors de leurs déplacements à travers la matière et, éventuellement, sont arrêtées ou absorbées. Cet exemple explore le pouvoir d'arrêt des substances lorsqu'elles s'irradient par des particules alpha.

Tracez la puissance de freinage linéaire d'un tissu biologique lors d'une irradiation par des particules alpha de différentes énergies d'impact. L'axe vertical représente la quantité d'énergie que les particules perdent en moyenne par centimètre parcouru.

In[1]:=

ListLogLinearPlot[
 Table[{Quantity[10^x, "Electronvolts"], 
   StoppingPowerData[
    "A150TissueEquivalentPlastic", {"Particle" -> 
      Entity["Particle", "AlphaParticle"], 
     "Energy" -> Quantity[10^x, "Electronvolts"]}, 
    "LinearStoppingPower"]}, {x, 3, 8, 0.1}], AxesLabel -> Automatic]

Out[1]=

Maintenant explorez comment la puissance de freinage linéaire change pour une particule alpha émise par un atome d'uranium lorsque la particule se déplace à travers les tissus biologiques. Ceci est l'énergie cinétique initiale de la particule.

In[2]:=

initialKE = 
 IsotopeData[Entity["Isotope", "Uranium235"], "BindingEnergy"]

Out[2]=

Montrer l'entrée complète de Wolfram Language

In[3]:=

dEByDxVal[k_Real?Positive] := 
  QuantityMagnitude[
    StoppingPowerData[
     "A150TissueEquivalentPlastic", {"Particle" -> 
       Entity["Particle", "AlphaParticle"], 
      "Energy" -> Quantity[k, "Megaelectronvolts"]}, 
     "LinearStoppingPower"]]/10000;
dEByDxVal[k_Real] := 0

In[4]:=

sol = NDSolveValue[{KiM'[x] == -dEByDxVal[KiM[x]], 
    KiM[0] == QuantityMagnitude[initialKE],
      WhenEvent[KiM[x] <= 0, "StopIntegration"]}, KiM, {x, 0, 60},
    PrecisionGoal -> 3];

Représentez la diminution en énergie cinétique de la pendant que la particule avance à travers le matériau jusqu'à ce qu'il s'arrête à 60µm environ.

Montrer l'entrée complète de Wolfram Language

In[5]:=

Plot[sol[x], {x, 0, 60}, Frame -> True, GridLines -> Automatic, 
 FrameLabel -> {"distance traveled (\[Micro]m)", 
   Row[{"KE", " (", Quantity[None, "Megaelectronvolts"], ")"}]}]

Out[5]=

Cela représente le taux de perte d'énergie par unité de longueur.

Montrer l'entrée complète de Wolfram Language

In[6]:=

Plot[dEByDxVal[sol[x]], {x, 0, 60}, Frame -> True, 
 GridLines -> Automatic, 
 FrameLabel -> {"distance traveled (\[Micro]m)", 
   Row[{"\[DifferentialD]", Style["E", Italic], "/", 
     "\[DifferentialD]", Style["x", Italic], " (", 
     Quantity[None, "Megaelectronvolts"/"Micrometers"], ")"}]}]

Out[6]=