Túneles

TunnelData proporciona información acerca de túneles, tales como longitud y ubicación.

In[1]:=

tunnels = TunnelData[];

In[2]:=

Length[tunnels]

Out[2]=

Para cada túnel, encuentre su longitud y ubicación dada por país o países.

In[3]:=

rawData = TunnelData[tunnels, {"Countries", "Length"}];

Limpie los datos para remover valores faltantes.

In[4]:=

data = DeleteMissing[rawData, 1, 2];

Convierta los datos de longitud a millas.

In[5]:=

data[[All, 2]] = UnitConvert[N[data[[All, 2]]], "Miles"];

In[6]:=

lengths = data[[All, 2]];

In[7]:=

MinMax[lengths]

Out[7]=

In[8]:=

h = Histogram[lengths, {1, 12, .5}, PDF, FrameLabel -> Automatic, PlotTheme -> "Detailed"]

Out[8]=

Los datos pueden ser descritos por una mezcla de distribuciones de cola larga.

In[9]:=

dist = MixtureDistribution[{w1, w2}, {ParetoDistribution[a1, a2, a3, a4], WeibullDistribution[b1, b2]}];

In[10]:=

edist = EstimatedDistribution[lengths, dist]

Out[10]=

Pruebe lo bueno del ajuste contra distribuciones de mezcla de la familia paramétrica.

In[11]:=

DistributionFitTest[lengths, dist, "TestDataTable"]

Out[11]=

Represente gráficamente el PDF de la distribución ajustada contra el histograma.

In[12]:=

Show[h, Plot[PDF[edist, Quantity[x, "Miles"]], {x, 1, 12}, PlotRange -> All] // Quiet]

Out[12]=

Visualice las ubicaciones de los túneles.

Agrupe por país.

In[13]:=

res = GroupBy[data, First, Flatten[Take[#, All, -1]] &];

Algunos túneles están ubicados en más de un país.

In[14]:=

shared = Select[Keys[res], Length[#] > 1 &]

Out[14]=

Distribuya los túneles compartidos y selecciones los países que tiene al menos 10 túneles. Represente gráficamente la table de distribución de longitud.

In[15]:=

split = GroupBy[ Flatten[Map[{{{#[[1]]}, res[#]}, {{#[[2]]}, res[#]}} &, shared], 1], First, Flatten[#[[All, 2]]] &];

In[16]:=

together = Join[KeyDrop[res, shared], split, 2];

In[17]:=

tc = SortBy[Select[Normal[together], Length[#[[2]]] >= 10 &], Length@*Last];

In[18]:=

DistributionChart[tc[[All, 2]], ChartLabels -> tc[[All, 1, 1]], BarOrigin -> Left, BarSpacing -> .3, FrameLabel -> {"Miles"}, LabelingFunction -> (Placed[Length[#1], After] &), ChartStyle -> "SandyTerrain", ImageSize -> Large]

Out[18]=

El millaje total de los túneles por país con los túneles compartidos está incluido en la longitud total para cada país.

In[19]:=

vals = KeyMap[First, Map[Total, together]]; title = Style["tunnel mileage", 24, Bold, GrayLevel[.2], FontFamily -> "Osaka"]; GeoRegionValuePlot[vals, GeoProjection -> "Mercator", GeoRange -> {{-65, 80}, {-170, 190}}, PlotLegends -> Automatic, ColorFunction -> (ColorData["StarryNightColors", 2 #] &), Epilog -> Inset[title, {30, -65}], ImageSize -> 500]

Out[19]=