Wolfram Language™

Reactores nucleares del mundo

NuclearReactorData proporciona datos de los reactores nucleares conocidos en todo el mundo. Algunos de ellos ya han sido cerrados, como el de Chernobyl. Usted puede seleccionar los reactores que están operando hoy en día para el análisis de recursos de energía nuclear.

In[1]:=

reactors = NuclearReactorData[];

In[2]:=

active = Select[reactors, #["Status"] == "operational" &];

Extraiga la producción de energía anual y el país donde se ubica.

In[3]:=

annualproduction = NuclearReactorData[active, "AnnualEnergyProduction"]; countries = Map[First, NuclearReactorData[active, "Countries"]];

Cree una base de datos y elimine los puntos de datos que contengan valores faltantes. El número de reactores en funcionamiento es mayor a 400.

In[4]:=

data = Transpose[{active, countries, annualproduction}]; data = DeleteMissing[data, 1, 2];

In[5]:=

data // Dimensions

Out[5]=

El número de reactores por país.

In[6]:=

percountry = GroupBy[data, #1[[2]] &];

In[7]:=

numberpercountry = Map[Length, percountry];

In[8]:=

BarChart[Sort[numberpercountry], ChartLabels -> Automatic, ChartStyle -> "DarkRainbow", BarOrigin -> Left, BarSpacing -> 1, LabelingFunction -> (Placed[#1, After] &), ImageSize -> Large]

Out[8]=

El número de reactores corresponde al total de energía nuclear producida por país.

In[9]:=

energytotals = Map[Total[#[[All, 3]]] &, percountry];

In[10]:=

stats = {Min, Max, Mean, Median, Total}; TableForm[#[energytotals] & /@ stats, TableHeadings -> {stats}]

Out[10]//TableForm=

Los mayores productores de energía nuclear son Estados Unidos y Francia.

In[11]:=

TakeLargest[energytotals, 2]

Out[11]=

In[12]:=

GeoRegionValuePlot[energytotals, GeoProjection -> "Mercator", GeoRange -> {{-70, 80}, {-170, 190}}, GeoLabels -> (Tooltip[#1, #2] &)]

Out[12]=

El mapa se ve distinto si usted considera la producción de energía total por persona. Utilice CountryData para acceder a los totales de población de cada país en la lista.

In[13]:=

populations = AssociationThread[Keys[energytotals], CountryData[#, "Population"] & /@ Keys[energytotals]];

Calcule la energía nuclear por persona.

In[14]:=

energypercapita = energytotals/populations;

In[15]:=

TableForm[#[energypercapita] & /@ stats, TableHeadings -> {stats}]

Out[15]//TableForm=

En el mapa, usted puede ver que aunque Estados Unidos tiene la producción de energía nuclear absoluta más alta, no es la más alta por persona, donde Francia y Suecia lideran.

In[16]:=

TakeLargest[energypercapita, 2]

Out[16]=

In[17]:=

GeoRegionValuePlot[energypercapita, GeoProjection -> "Mercator", GeoRange -> {{-70, 80}, {-170, 190}}, GeoLabels -> (Tooltip[#1, #2] &)]

Out[17]=